!  Th2LS_1.INP  - программа для ANSYS
!	Предметная область - теплофизика (Th)
!	Плоская задача (2)
!	Линейный анализ (L)
!	Стационарная задача (S)
!
!	Тестовая задача, иллюстрирующая решение
!	краевой задачи для уравнения теплопроводности
!	с различными типами граничных условий.
!
!	Геометрия области - тело в форме буквы "R".

/TITLE, Heat Flow in 2D region (R)
/PREP7

!  Все величины в системе Си

! Геометрические размеры тела в форме буквы "R"
HL=1.4 	 ! Высота 
WL=0.8   ! Ширина 
WWL=0.2 ! Ширина стенок буквы "R"
HAL=0.7 ! Дополнительный размер по высоте

T_INP1=90   ! Температура на левой части нижней границе
T_INP2=180   ! Температура на правой части нижней границе
T_EXT=0	! Температура окружающей среды для конвективных условий T_EXT=0
H_F=60	! Коэффициент конвективного теплообмена

MP,KXX,1,46.7 ! Коэффициент теплопроводности KXX=46.7 (Сталь)

! Параметры для триангуляции
DMESH=WWL/2
DMESH1=DMESH/4

ET,1,PLANE35 ! Шестиузловой треугольный температурный КЭ PLANE35

PEL=(HAL/2)/(WL-WWL) ! Параметр эллиптичности для криволинейной части фигуры
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Эллиптическая система координат 11
CSYS,0	! Переход в основную декартову систему координат

! Определение основных опорных точек для внешней границы
K,1,0,0
K,2,WWL,0
K,3,WWL,HL-HAL-WWL
K,4,WL-WWL,0
K,5,WL,0
K,6,WWL,HL-HAL
K,7,WL,HL-HAL/2
K,8,WWL,HL
K,9,0,HL

 !   создание линий по точкам
L,1,2 $ L,2,3  $ L,3,4 $ L,4,5 $ L,5,6
CSYS,11    ! Переход в систему координат с номером 11
L,6,7 $ L,7,8
CSYS,0 ! Переход в основную декартову систему координат
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 ! Определение площади 1 по линиям

! Определение отверстия - площади 2
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL
K,11,WL-WWL,HL-HAL/2
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL
CSYS,11
L,10,11 $ L,11,12
CSYS,0
L,12,10
AL,10,11,12
ASBA,1,2 ! Вырезать из области 1 область 2

! Установка размеров элементов вблизи опорных точек
KESIZE,ALL,DMESH
KESIZE,3,DMESH1 $ KESIZE,6,DMESH1 
KESIZE,10,DMESH1 $ KESIZE,11,DMESH1 $ KESIZE,12,DMESH1 
AMESH,ALL ! Триангулировать область (3)
FINISH

/SOLU
ANTYPE,STAT          ! Решение стационарной задачи
NSEL,S,LOC,Y,0	! Выбор всех узлов с координатой Y=0
NSEL,R,LOC,X,0,WWL
D,ALL,TEMP,T_INP1	! Задать для всех выбранных узлов TEMP=T_INP1
NSEL,S,LOC,Y,0	! Выбор всех узлов с координатой Y=0
NSEL,R,LOC,X,WL,WL-WWL
D,ALL,TEMP,T_INP2	! Задать для всех выбранных узлов TEMP=T_INP2
NSEL,S,LOC,Y,HL	! Выбор всех узлов с координатой Y=HL
NSEL,R,LOC,X,0,WWL
SF,ALL,CONV,H_F,T_EXT ! Конвективный теплообмен в выбранных узлах
NSEL,ALL		! Вернуться к выбору всех узлов модели

SOLVE			! Решить СЛАУ МКЭ
SAVE,Heat_Letter_R,db   ! Сохранить базу ANSYS задачи под именем Heat_Letter_R.db
FINISH

/POST1
!  Команды, управляющие форматом графического вывода
/SHOW,WIN32C
/TRIAD,OFF         ! Не показывать начала координат и осей
/PLOPTS,INFO,2     ! Использовать формат вывода Auto-legend для подписей
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,TITLE,OFF  ! Не показывать заголовок
/PLOPTS,MINM,ON
/PLOPTS,DATE,OFF   ! Не показывать дату
! Для показа распределений величин использовать 14 градаций уровней
/CONT,,14
! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PBC,TEMP,,1	!   Отображать граничные условия для температуры
/PSF,CONV,HCOEF,2 !   Отображать стрелками граничные условия с коэффициентом теплообмена
PLNSOL,TEMP		!   Показать поле температуры