!       ANSYS  REL. 9.0, 10.0,     VERIF. St2LM_1
!	Предметная область - теория упругости - структурный анализ (St)
!	Плоская задача (2)
!	Линейный анализ (L)
!	Модальный анализ (M)
!
!	Тестовая задача, иллюстрирующая технику
!	решения задачи на собственные частоты (Модальный анализ)
!	для системы уравнений теории упругости
!	(плоское напряженное состояние).
!
!	Геометрия области --- плоское тело в форме двутавра.
!       Двутавр состоит из двух различных материалов

/FILNAME,St2LM_1
/TITLE, Modal Analysis of a Double-T Region
F_R='Mod_ANS_1'        ! имя файлов для вывода результатов

!JPGPRF,500,100,1      ! Макро файл для вывода графики в формате *.jpg
!/SHOW,JPEG 

NFREQ=4        !  число выводимых частот и мод колебаний

/PREP7

H=0.02 ! Толщина
B=0.16 ! Полувысота
L=0.05 ! Полуширина планки

! Параметры для триангуляции
DH=1
KFE=H

/OUTPUT,F_R,res
*VWRITE
(1X,'   MODE-FREQUENCY ANALYSIS (Block Lanczos, Plane2)')

*VWRITE,NFREQ
(1X,'   NFREQ= ',F4.0)
/OUTPUT

*DIM,FR,ARRAY,NFREQ  ! массив для собственных частот

!  Материальные константы стали
RO1=7.86e3  ! плотность
E1=2e11     ! модуль Юнга
NU1=0.29    ! коэффициент Пуассона

!  Материальные константы меди
RO2=8.9e3
E2=1.2e11
NU2=0.33
    
MP,DENS,1,RO1       !  плотность среды 1
MP,EX,1,E1          !  модуль Юнга среды 1
MP,NUXY,1,NU1       !  коэффициент Пуассона среды 1
    !
MP,DENS,2,RO2       !  плотность среды 2
MP,EX,2,E2          !  модуль Юнга среды 2
MP,NUXY,2,NU2       !  коэффициент Пуассона среды 2
    
ET,1,PLANE2    ! старый КЭ PLANE2
!ET,1,PLANE82    ! новый КЭ PLANE82:  8-узловой четырехугольный
!mshape,1 ! опция треугольной формы для элементов

! Определение основных точек
K,1,H/2,0
K,2,H/2,B-H
K,3,L,B-H
K,4,L,B
K,5,-L,B
K,6,-L,B-H
K,7,-H/2,B-H
K,8,-H/2,0

K,9,H/2,-B+H
K,10,L,-B+H
K,11,L,-B
K,12,-L,-B
K,13,-L,-B+H
K,14,-H/2,-B+H

! Определение линий 1-7
L,1,2 $ L,2,3 $ L,3,4 $ L,4,5
L,5,6 $ L,6,7 $ L,7,8 $ L,8,1
AL,1,2,3,4,5,6,7,8 ! Определение области 1 по линиям 1-8
! Определение линий 9-15
L,1,9 $ L,9,10 $ L,10,11 $ L,11,12
L,12,13 $ L,13,14 $ L,14,8
AL,8,9,10,11,12,13,14,15 ! Определение области 2 по линиям 8-15

! Установка размеров конечных элементов
KESIZE,ALL,KFE
LESIZE,8,,,DH  ! Линию 8 разбить на DH частей

ASEL,S,AREA,,2   ! Выделяем новое множество областей - область 2
AATT,2,,1  ! Ассоциируем с выделенной областью
            ! атрибуты: MAT=2,  TYPE=1
ASEL,ALL  ! Возврат к выбору всех областей

AMESH,ALL ! Триангулировать все области (1 и 2)

*GET,EL_MAX,ELEM,,COUNT  ! EL_MAX - число элементов
*GET,ND_MAX,NODE,,COUNT  ! ND_MAX - число узлов
/OUTPUT,F_r,res,,append
*VWRITE,EL_MAX,ND_MAX
(3X,' NEL_MAX=',F6.0,' NND_MAX=',F6.0)
/COM,
/COM,  i   ! Frequency in Hz (ANSYS)
/OUTPUT

SAVE
FINISH

/SOLU
ANTYPE,MODA          ! Решение задач на собственные значения.
MODOPT,LANB,NFREQ ! Метод решения - Block Lanczos,
                   ! число частот и мод - NFREQ
NSEL,S,LOC,Y,-B	! Выбор всех узлов с координатой Y=-B
D,ALL,UX,0    ! Для всех выделенных узлов UX=0,
D,ALL,UY,0    !                           UY=0
NSEL,ALL      ! Возврат к выбору всех узлов

OUTRES,ALL,ALL ! Запись результатов для всех найденных частот
SOLVE
SAVE
FINISH

/POST1
 ! Вывод таблицы резонансных частот в файл
*DO,I,1,NFREQ
  SET,,I
  *GET,FR(I),MODE,I,FREQ
  FRI=FR(I)
  /OUTPUT,F_r,res,,append
  *VWRITE,I,FRI
  (1X,F4.0,'   ',E12.5)
  /OUTPUT
*ENDDO