!
!         Файл    St2LH_AFC_1.inp
!       Расчет установившихся колебаний
!       составного "двутаврового" профиля
!
!    Построение амплитудно-частотной характеристики
!    в окрестности двух резонансных частот
!
!    Программа использует базу данных ANSYS  St2LM_1.db,
!   созданную при расчете задачи на собственные значения

RESUME,St2LM_1,db ! считываем базу данных (St2LM_1.db)

F_R='Harm1'        ! имя файлов для вывода результатов
/SHOW

FORC=1e3
FBEG=50       !  начало исследуемого частотного интервала
FEND=900       !  конец частотного интервала
NFREQ=250       !  число рассчитываемых значений по частотам
F1=97.4 $ F2=729.0   

/OUTPUT,F_R,rez
*VWRITE
(1X,'   HARMONIC ANALYS ')
*VWRITE,FBEG,FEND
(1X,'  FBEG=', E12.5,'  FEND=', E12.5)
*VWRITE,NFREQ
(1X,'    NFRQ= ',F4.0)
/OUTPUT

/COM,   Демпфирующие свойства 
PI2=(3.141593*2)
IPI2=1./PI2
FDB=F1
FDE=F2
FRDS=FDB+FDE
Q=1000           ! Добротность конструкции
ADAMP=PI2*FDB*FDE/(FRDS*Q) 
BDAMP=IPI2/(FRDS*Q)

/OUTPUT,F_R,rez,,append
*VWRITE,FDB,FDE
(1X,'   FDB=', E12.5,'  FDE=', E12.5)
*VWRITE,Q
(1X,' Q=', F12.5)
*VWRITE,ADAMP,BDAMP
(1X,'  ADAMP=', E12.5,' BDAMP=',E12.5)
/OUTPUT

/SOLU
ANTYPE,HARMIC          ! Решение задачи об установившихся колебаниях.
HARFRQ,FBEG,FEND       ! Задается расчетный интервал частот.
NSUBST,NFREQ           ! Число частот на заданном интервале: NFREQ.
KBC,1                  ! Постоянное значение амплитуд сил.

ALPHAD,ADAMP  
BETAD,BDAMP

NSEL,S,LOC,X,L     
NSEL,R,LOC,Y,B
*GET,N_RES2,NODE,,NUM,MIN ! Узел с номером N_RES2 - точка (L,B)
NSEL,S,LOC,X,-L     
NSEL,R,LOC,Y,B
*GET,N_RES1,NODE,,NUM,MIN ! Узел с номером N_RES1 - точка (-L,B)
NSEL,ALL

F,N_RES2,FX,FORC
F,N_RES2,FY,FORC
F,N_RES1,FX,-FORC
F,N_RES1,FY,-FORC

OUTRES,BASIC,ALL ! Сохраняем основные результаты для всех частот
SOLVE
SAVE
FINISH

/POST26
/XRANG,FBEG,FEND
/AXLAB,X,Frequency (Hz)
/AXLAB,Y,Displacement (M)
NSOL,2,N_RES2,UY
PLVAR,2