/TITLE, Thermal stress in 3D region (R)
/PREP7

!  Все величины в системе Си

! Геометрические размеры тела в форме буквы "R"
HL=1.4 	 ! Высота 
WL=0.8   ! Ширина 
WWL=0.2 ! Ширина стенок буквы "R"
HAL=0.7 ! Дополнительный размер по высоте

! Параметры для триангуляции
DMESH=WWL/3

ET,1,SOLID98,0  ! Тип конечного - трехмерный твердотельный 10-узловой SOLID98
                        ! Степени свободы UX, UY, UZ, TEMP, VOLT, MAG, используются первые четыре

PEL=(HAL/2)/(WL-WWL) ! Параметр эллиптичности для криволинейной части фигуры
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Эллиптическая система координат 11
CSYS,0	! Переход в основную декартову систему координат

! Определение основных опорных точек для внешней границы
K,1,0,0
K,2,WWL,0
K,3,WWL,HL-HAL-WWL
K,4,WL-WWL,0
K,5,WL,0
K,6,WWL,HL-HAL
K,7,WL,HL-HAL/2
K,8,WWL,HL
K,9,0,HL

 !   создание линий по точкам
L,1,2 $ L,2,3  $ L,3,4 $ L,4,5 $ L,5,6
CSYS,11    ! Переход в систему координат с номером 11
L,6,7 $ L,7,8
CSYS,0 ! Переход в основную декартову систему координат
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 ! Определение площади 1 по линиям

! Определение отверстия - площади 2
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL
K,11,WL-WWL,HL-HAL/2
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL
CSYS,11
L,10,11 $ L,11,12
CSYS,0
L,12,10
AL,10,11,12
ASBA,1,2 ! Вырезать из области 1 область 2

! Установка размеров элементов 
ESIZE,DMESH

! Определение точек оси, отстоящей от плоской области слева на WWL
K,1001,-WWL,0
K,1002,-WWL,HL

! Создать объем вращением области 3 вокруг оси с точками 1001 и 1002 на 45 градусов
VROTAT,3,,,,,,1001,1002,45  

LSEL,S,LINE,,22,30,8 ! Выбор линий 22 и 30
LESIZE,ALL,,,5 ! Разбиение выбранных линий на 5 частей
VMESH,ALL ! Разбить все объемы на конечные элементы

!------------------------------------------------------------
! "Температурные" материальные свойства
T_INP1=90   ! Температура на левой части нижней границе
T_INP2=180   ! Температура на правой части нижней границе
T_EXT=0	! Температура окружающей среды для конвективных условий T_EXT=0
H_F=60	! Коэффициент конвективного теплообмена

MP,KXX,1,46.7 ! Коэффициент теплопроводности KXX=46.7 (Сталь)

ALPH1=1.51e-05 !коэффициент теплового расширения
MP,ALPX,1,ALPH1 
!---------------------------------------------------------------
! "Упругие" материальные свойства
!   Материальные константы стали
RO1=7.8e3 ! плотность
E1=2.1e11 !модуль Юнга
NU1=0.29 !коэффициент Пуассона

MP,DENS,1,RO1   
MP,EX,1,E1      
MP,NUXY,1,NU1  
!----------------------------------------------------------------- 

! Решение связанной задачи термоупругости
/SOLU
ANTYPE,STAT          ! Решение стационарной задачи
! Условия для "температурного" анализа
TREF,0 ! Определение относительной температуры (в градусах)
!  Определение новой системы координат - 
!  цилиндрической с осью Z'', совпадающей с осью поворота 
LOCAL,12,1,-WWL,0,0,,-90
CSYS,12
NSEL,S,LOC,Z,0	! Выбор всех узлов с координатой Z''=0
NSEL,R,LOC,X,WWL,2*WWL
D,ALL,TEMP,T_INP1	! Задать для всех выбранных узлов TEMP=T_INP1
NSEL,S,LOC,Z,0	! Выбор всех узлов с координатой Z''=0
NSEL,R,LOC,X,WL+WWL,WL
D,ALL,TEMP,T_INP2	! Задать для всех выбранных узлов TEMP=T_INP2
NSEL,S,LOC,Z,HL,HL	! Выбор всех узлов с координатой Z''=HL
NSEL,R,LOC,X,WWL,2*WWL
SF,ALL,CONV,H_F,T_EXT ! Конвективный теплообмен в выбранных узлах
NSEL,ALL		! Вернуться к выбору всех узлов модели
CSYS,0
! Условия для "упругого" анализа
ASEL,S,AREA,,1,5,4
NSLA,S,1
D,ALL,UX,0
D,ALL,UY,0
D,ALL,UZ,0
ASEL,ALL
NSEL,ALL		! Вернуться к выбору всех узлов модели

SOLVE			! Решить СЛАУ МКЭ
FINISH