! О С Е С И М М Е Т Р И Ч Н А Я З А Д А Ч А
! П Ь Е З О Э Л Е К Т Р И Ч Е С К И Й Д И С К

! Статическая задача
! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15
! Заголовок для решаемой задачи ("пьезоэлектрический диск")

/TITLE, PIEZOELECTRIC DISC
! Параметры для геометрических размеров (все - в системе СИ)
H=0.002 ! толщина диска
R=10*H ! радиус диска
! Впомогательные геометрические размеры
R1=R/4 ! радиус внутренней электродированной поверхности
R23=R/4 ! размер по радиусу для кольцевой электродированной поверхности
! Значение подаваемого электрического потенциала на электрод
VINP=1

! Параметры конечно-элементной сетки
SM=1 ! масштабный множитель (scaling multiplier)
HDIV=8*SM ! Кол-во КЭ по толщине диска (должно быть четным числом!)
R1DIV=16*SM ! Кол-во КЭ по радиальному направлению от 0 до R1
R12DIV=32*SM ! Кол-во КЭ по радиальному направлению от R1 до R2
R23DIV=16*SM ! Кол-во КЭ по радиальному направлению от R2 до R

! Параметры для материальных констант пьезокерамики PZT-4
! (все данные - в системе СИ)
RO=7.5e3 ! плотность
C11E=13.9e10 ! упругие модули C^E_ij
C12E=7.78e10
C13E=7.43e10
C33E=11.5e10
C66E=(C11E-C12E)/2.
C44E=2.56e10
E31=-5.2 ! пьезомодули
E33=15.1
E15=12.7
EPS11=730 ! диэлектрические проницаемости, отнесенные к проницаемости вакуума
EPS33=635

/PREP7 ! (Preprocessor) 
!Вход в препроцессор
! Занесение материальных констант пьезокерамического материала в массивы данных
! (для случая осесимметричной задачи и пьезокерамики, поляризованной по оси)
MP,DENS,1,RO
TB,ANEL,1
TBDATA,1,C11E,C13E,C12E
TBDATA,7,C33E,C13E
TBDATA,12,C11E
TBDATA,16,C44E
TB,PIEZ,1
TBDATA,2,E31
TBDATA,5,E33
TBDATA,8,E31
TBDATA,10,E15
MP,PERX,1,EPS11
MP,PERY,1,EPS33

ET,1,PLANE223,1001,,1 ! 2D четырехугольный КЭ с 8 узлами для связанных задач
! KEYOPT(1)=1001 - степени свободы UX,UY,VOLT (пьезоэлектрический КЭ)
! KEYOPT(3)=1 - осесимметричная задача

R2=R-R23 ! Вспомогательный геометрический размер по радиусу

! Определение опорных точек 
K,1,0,-H/2 ! (Keypoint) точка с номером 1 с координатами x=0, y=-H/2
K,2,R1,-H/2
K,3,R2,-H/2
K,4,R,-H/2
K,5,R,H/2
K,6,R2,H/2
K,7,R1,H/2
K,8,0,H/2

! Определение прямых линий, соединяющих точки
L,1,2 ! (Line) линия, соединяющая точки 1 и 2 (будет иметь номер 1)
L,2,3 $ L,3,4 ! линии 2 и 3, знак $ - для разделения команд, записанных в одной строке
L,4,5 $ L,5,6 $ L,6,7 $ L,7,8 $ L,8,1 $ L,6,3 ! линии 4-9

! Построение областей (площадей) по опорным точкам
! Точки должны быть перечислены в порядке обхода
A,1,2,3,6,7,8 ! (Area) область 1
A,3,4,5,6 ! область 2

! Определение локальной системы координат с номером 11,
! повернутой относительно оси z на 180 градусов
LOCAL,11,0,,,,180
! (Change System)
CSYS,0 ! Переход в систему координат с номером 0 (глобальную декартову)

! Задание для области 2 элементной системы координат 11
! (для задания направления поляризации)
ASEL,S,AREA,,2 ! (Area Select) Выбор области 2
! AATT - задание специальных атрибутов для еще не разбитых на КЭ областей
AATT,1,,1,11 ! 11 - номер элементной системы координат для выбранной области
! необязательные команды
ASEL,S,AREA,,1
AATT,1,,1
ASEL,ALL ! возврат к выбору всех областей

! Разбиение линий для канонической конечно-элементной сетки
! Важно: суммарное число делений для противоположных линий области
! должно быть одинаковым!
! Выбор всех вертикальных линий (это линии L8, L9, L4)
LSEL,S,LINE,,8,9
LSEL,A,LINE,,4
! Для всех выбранных линий зададим разбиение на одно и то же число частей
! LESIZE - (Line Element Size) Задание числа делений для неразбитых линий
LESIZE,ALL,,,HDIV ! для выбранных линий задается число делений HDIV
LSEL,S,LOC,X,0,R1 ! Выбор линий с координатой 0<=X<=R1, это линии L1 и L7
LESIZE,ALL,,,R1DIV ! для выбранных линий задается число делений R1DIV
LSEL,S,LOC,X,R1,R2 ! Выбор линий с координатой R1<=X<=R2, это линии L2 и L6
LESIZE,ALL,,,R12DIV ! для выбранных линий задается число делений R2DIV
LSEL,S,LOC,X,R2,R ! Выбор линий с координатой R2<=X<=R, это линии L3 и L5
LESIZE,ALL,,,R23DIV ! для выбранных линий задается число делений R23DIV
LSEL,ALL ! возврат к выбору всех линий

! Превращение нерегулярной области 1 в регулярную
LCCAT,1,2 ! Конкатенация линий L1 и L2, в результате будет линия L10
LCCAT,7,6 ! Конкатенация линий L7 и L6, в результате будет линия L11
MSHKEY,1 ! (Mesh Key) задает ключ разбиения
! (0 - свободное разбиение, 1 - регулярное разбиение)
MSHAPE,0,2 ! (Mesh Shape) задает форму конечных элементов
! 1й аргумент - ключ формы элементов (0 - разбиение на четырехугольные КЭ)
! 2й аргумент - размерность модели (2D - разбиение плоских областей)
AMESH,ALL ! (Area Mesh) Команда построения конечно-элементной сетки на областях
FINISH ! выход из процессора

/SOLU ! (Solution) Вход в решатель
ANTYPE,STAT ! Выбор типа анализа (STATic - решение статической задачи)

! Определение электродов
! Выбор узлов для первого электрода (с координатами 0<=X<=R1, Y=-H/2)
NSEL,S,LOC,Y,-H/2
NSEL,R,LOC,X,0,R1
! Объединение степеней свободы VOLT всех выбранных узлов в группу с номером 1
CP,1,VOLT,ALL
! Задание параметра N_VOLT1 - минимального номера узла из группы 1
! Узел с номером N_VOLT1 будет ссылочным узлом группы 1
*GET,N_VOLT1,NODE,,NUM,MIN

! Выбор узлов для второго электрода (с координатами 0<=X<=R1, Y=H/2)
NSEL,S,LOC,Y,H/2
NSEL,R,LOC,X,0,R1
! Объединение степеней свободы VOLT всех выбранных узлов в группу с номером 2
CP,2,VOLT,ALL
! Задание параметра N_VOLT2 - минимального номера узла из группы 2
! Узел с номером N_VOLT2 будет ссылочным узлом группы 2
*GET,N_VOLT2,NODE,,NUM,MIN

! Выбор узлов для третьего электрода (с координатами R2<=X<=R, Y=-H/2)
NSEL,S,LOC,Y,-H/2
NSEL,R,LOC,X,R2,R
! Объединение степеней свободы VOLT всех выбранных узлов в группу с номером 3
CP,3,VOLT,ALL
! Задание параметра N_VOLT3 - минимального номера узла из группы 3
! Узел с номером N_VOLT3 будет ссылочным узлом группы 3
*GET,N_VOLT3,NODE,,NUM,MIN

! Выбор узлов для четвертого электрода (с координатами R2<=X<=R, Y=H/2)
NSEL,S,LOC,Y,H/2
NSEL,R,LOC,X,R2,R
! Объединение степеней свободы VOLT всех выбранных узлов в группу с номером 4
CP,4,VOLT,ALL
! Задание параметра N_VOLT4 - минимального номера узла из группы 4
! Узел с номером N_VOLT4 будет ссылочным узлом группы 4
*GET,N_VOLT4,NODE,,NUM,MIN

NSEL,ALL ! Возврат к выбору всех узлов модели

! Определение значений потенциалов на электродах
D,N_VOLT1,VOLT,-VINP
D,N_VOLT2,VOLT,VINP
D,N_VOLT3,VOLT,-VINP
D,N_VOLT4,VOLT,VINP

! Условия симметрии относительно оси OY (на этой оси лежит линия 8)
DL,8,,SYMM

! Условие закрепления срединной крайней точки по оси Y
! Выбор узла с координатами X=R, Y=0
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,R
D,ALL,UY,0 ! Задание ограничений UY=0 в узлах
NSEL,ALL ! Возврат к выбору всех узлов
SOLVE ! Решить систему МКЭ
FINISH ! Выход из процессора

! Вход в общий постпроцессор
/POST1 ! Команды, управляющие форматом графического вывода
! Вывод картины распределения перемещений UY PLNSOL,U,Y
PLNSOL,U,Y