/TITLE, Thermal stress in 3D region (R)
/PREP7

! Input data in SI system

! Geometrical sizes of the 2D domain in the shape of the letter "R"
HL=1.4 	 ! Height
WL=0.8   ! |Width 
WWL=0.2 ! width of the walls of "R"
HAL=0.7 ! additional parameter

! Parameters for finite element mesh
DMESH=WWL/3

ET,1,SOLID98,0  ! 10-node 3D SOLID98
! Degrees of freedom: UX, UY, UZ, TEMP, VOLT, MAG. Only the first four are used in this analysis

PEL=(HAL/2)/(WL-WWL) ! Ellipticity parameter for the curved part of the figure
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Elliptical coordinate system 11
CSYS,0	! Change active coordinate system to Cartesian

! Define main keypoints for external boundary
K,1,0,0
K,2,WWL,0
K,3,WWL,HL-HAL-WWL
K,4,WL-WWL,0
K,5,WL,0
K,6,WWL,HL-HAL
K,7,WL,HL-HAL/2
K,8,WWL,HL
K,9,0,HL

! Define lines by end keypoints
L,1,2 $ L,2,3  $ L,3,4 $ L,4,5 $ L,5,6
CSYS,11    ! Change active coordinate system to coordinate system 11
L,6,7 $ L,7,8
CSYS,0 ! Change active coordinate system to Cartesian
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 ! ! Define area 1 by lines

!Define the hole - area 2
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL
K,11,WL-WWL,HL-HAL/2
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL
CSYS,11
L,10,11 $ L,11,12
CSYS,0
L,12,10
AL,10,11,12
ASBA,1,2 ! Substract area 2 from area 1

! Define element sizes in the vicinity of the keypoints 
ESIZE,DMESH

! 3D geometry from 2D using rotation
! Define keypoints for an axis of rotation (parallel to y-axis)
K,1001,-WWL,0
K,1002,-WWL,HL

! Create volume by rotating area 3 around the axis defined by points 1001 and 1002 for an angle of 45 degrees
VROTAT,3,,,,,,1001,1002,45  

LSEL,S,LINE,,22,30,8 ! Select lines 22 and 30
LESIZE,ALL,,,5 ! Divide selected lines in 5 segments
VMESH,ALL ! Mesh all volumes

!------------------------------------------------------------
! "Thermal" material properties
T_INP1=90   ! Temperature at the left bottom edge
T_INP2=180   ! Temperature at the right bottom edge
T_EXT=0	! Temperature of exernal medium T_EXT=0
H_F=60	! Convective heat transfer coefficient

MP,KXX,1,46.7 ! Thermal conductivity coefficient KXX=46.7 (Steel)

ALPH1=1.51e-05 ! Thermal expansion ratio
MP,ALPX,1,ALPH1 
!---------------------------------------------------------------
! "Elastic" material properties
!   Material properties of steel
RO1=7.8e3 ! density
E1=2.1e11 ! Young's modulus
NU1=0.29 ! Poisson's ratio

MP,DENS,1,RO1   
MP,EX,1,E1      
MP,NUXY,1,NU1  
!----------------------------------------------------------------- 

! Solve coupled thermoelastic problem
/SOLU
ANTYPE,STAT  ! Static analysis

! Boundary conditions for thermal analysis
TREF,0 ! Define reference temperature
! Define new cylindrical coordinate system with z-axis coincident with the axis of rotation (to further select the nodes)

LOCAL,12,1,-WWL,0,0,,-90
CSYS,12
NSEL,S,LOC,Z,0	! Select all nodes with Z''=0
NSEL,R,LOC,X,WWL,2*WWL
D,ALL,TEMP,T_INP1	! For all selected nodes define TEMP=T_INP1
NSEL,S,LOC,Z,0	! Select all nodes with Z''=0
NSEL,R,LOC,X,WL+WWL,WL
D,ALL,TEMP,T_INP2	! For all selected nodes define TEMP=T_INP2
NSEL,S,LOC,Z,HL,HL	!Select all nodes with Z''=HL
NSEL,R,LOC,X,WWL,2*WWL
SF,ALL,CONV,H_F,T_EXT ! For all selected nodes define convective heat transfer
NSEL,ALL		! Select all nodes
CSYS,0

! Boundary conditions for structural analysis
ASEL,S,AREA,,1,5,4
NSLA,S,1
D,ALL,UX,0
D,ALL,UY,0
D,ALL,UZ,0
ASEL,ALL
NSEL,ALL		! Select all nodes

SOLVE			! Solve the problem
FINISH