!  Th2LS_1.INP  - программа для ANSYS
!	Предметная область - теплофизика (Th)
!	Плоская задача (2)
!	Линейный анализ (L)
!	Стационарная задача (S)
!
!	Тестовая задача, иллюстрирующая решение
!	краевой задачи для уравнения теплопроводности
!	с различными типами граничных условий.
!
!	Геометрия области - тело в форме буквы "Ь".

/CLEAR ! Clear and start new
/TITLE, Heat Flow in 2D region
/PREP7 ! Вход в препроцессор

!  Все величины в системе Си

WL=0.04 	! Толщина буквы
T_INP=180	! Температура на нижней границе
T_EXT=0	! Температура окружающей среды для конвективных условий T_EXT=0
H_F=120	! Коэффициент конвективного теплообмена
MP,KXX,1,46.7 ! Коэффициент теплопроводности KXX=46.7 (Сталь)

! Параметры для триангуляции
DMESH=WL/2
DMESH1=DMESH/4

ET,1,PLANE35 ! Шестиузловой треугольный температурный КЭ PLANE35

PEL1=2/3
PEL2=(0.1-WL)/(0.15-WL)
LOCAL,11,1,0,0,,,,,PEL1 ! Эллиптическая система координат 11
LOCAL,12,1,0,0,,,,,PEL2 ! Эллиптич. сист. коорд. 12
CSYS,0	! Переход в основную декартову систему координат

! Определение основных опорных точек для внешней границы
K,1,0,-0.1
K,2,0.15,0
K,3,0,0.1
K,4,0,0.25
K,5,-WL,0.25
K,6,-WL,-0.1

CSYS,11    ! Переход в систему координат с номером 11
L,1,2 $ L,2,3   !   создание линий по точкам
CSYS,0
L,3,4 $ L,4,5 $ L,5,6 $ L,6,1 
AL,1,2,3,4,5,6 ! Определение площади 1 по линиям

! Определение отверстия - площади 2
K,7,0,-0.1+WL
K,8,0.15-WL,0
K,9,0,0.1-WL
CSYS,12
L,7,8 $ L,8,9
CSYS,0
L,9,7
AL,7,8,9
ASBA,1,2 ! Вырезать из области 1 область 2

! Установка размеров элементов вблизи опорных точек
!KESIZE,ALL,DMESH
ESIZE,DMESH
KESIZE,1,DMESH1 $ KESIZE,3,DMESH1 
KESIZE,7,DMESH1 $ KESIZE,9,DMESH1 
KESIZE,2,DMESH1 $ KESIZE,8,DMESH1 

AMESH,ALL ! Триангулировать область (3)
FINISH

/SOLU
ANTYPE,STAT          ! Решение стационарной задачи
LSEL,S,line,,6	! Выбор линии L6
DL,ALL,,TEMP,T_INP	! Задать для выбранной линии TEMP=T_INP
LSEL,ALL
!DL,6,,TEMP,T_INP
NSEL,S,LOC,Y,0.25	! Выбор всех узлов с координатой Y=0.25
SF,ALL,CONV,H_F,T_EXT ! Конвективный теплообмен в выбранных узлах
NSEL,ALL		! Вернуться к выбору всех узлов модели

ALLSEL,ALL ! ВЫБОР ВСЕХ СУЩНОСТЕЙ
SOLVE			! Решить СЛАУ МКЭ
FINISH

/POST1
!  Команды, управляющие форматом графического вывода
/SHOW,WIN32C
/TRIAD,OFF         ! Не показывать начала координат и осей
/PLOPTS,INFO,2     ! Использовать формат вывода Auto-legend для подписей
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,TITLE,OFF  ! Не показывать заголовок
/PLOPTS,MINM,ON
/PLOPTS,DATE,OFF   ! Не показывать дату
! Для показа распределений величин использовать 14 градаций уровней
/CONT,,14
! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PBC,TEMP,,1	!   Отображать граничные условия для температуры
/PSF,CONV,HCOEF,2 !   Отображать стрелками граничные условия с коэффициентом теплообмена
PLNSOL,TEMP		!   Показать поле температуры
!   Закомментированные команды для вывода теплового потока
!/PBC,TEMP,,0	!   Не показывать граничные условия для температуры
!/PSF,CONV,HCOEF,0 !  Не показывать граничные условия с коэффициентом теплообмена
! PLNSOL,TF,SUM   ! Показать модуль вектора теплового потока