!  Th2LS_1.INP  - программа для ANSYS
!	Предметная область - теплофизика (Th)
!	Плоская задача (2)
!	Линейный анализ (L)
!	Стационарная задача (S)
!
!	Тестовая задача, иллюстрирующая решение
!	краевой задачи для уравнения теплопроводности
!	с различными типами граничных условий.
!
!	Геометрия области - тело в форме буквы "Ь" с криволинейной частью в виде эллипсов

/CLEAR ! Clear and start new
/TITLE, Heat Flow in 2D region
/PREP7 ! Вход в препроцессор

!  Все величины в системе Си

! Геометрические размеры тела в форме буквы "Ь"
H=0.35 	 ! Высота 
W=0.19  ! Ширина 
WL=0.04 ! Ширина стенок буквы "Ь"
A=0.06 ! размер вертикальной полуоси внутреннего эллипса (малого)
B=W-2*WL ! размер горизонтальной полуоси внутреннего эллипса (малого)
A1=A+WL ! размер вертикальной полуоси внешнего эллипса (большого)
B1=W-WL ! размер горизонтальной полуоси внешнего эллипса (большого)
PEL0=A/B ! Параметр эллиптичности внутреннего малого эллипса (отношение вертикальной полуоси к горизонтальной)
PEL1=A1/B1 ! Параметр эллиптичности внешнего большого эллипса (отношение вертикальной полуоси к горизонтальной)

! Параметры для граничных условий
T_INP=180	! Температура на нижней границе
T_EXT=0	! Температура окружающей среды для конвективных условий T_EXT=0
H_F=120	! Коэффициент конвективного теплообмена

! Параметры для триангуляции
DMESH=WL/2
DMESH1=DMESH/4

MP,KXX,1,46.7 ! Коэффициент теплопроводности KXX=46.7 (Сталь)

ET,1,PLANE35 ! Шестиузловой треугольный температурный КЭ PLANE35

LOCAL,100,1,0,0,,,,,PEL0 ! Эллиптическая система координат 100 для малого эллипса
LOCAL,101,1,0,0,,,,,PEL1 ! Эллиптич. сист. коорд. 101 для большого эллипса

CSYS,0	! Переход в основную декартову систему координат

! Определение основных опорных точек для внешней границы
K,1,0,-A1
K,2,B1,0
K,3,0,A1
K,4,0,H-A1
K,5,-WL,H-A1
K,6,-WL,-A1

! Построение большого внешнего эллипса
CSYS,101    ! Переход в систему координат с номером 101
L,1,2 $ L,2,3   !   создание линий по точкам
CSYS,0
L,3,4 $ L,4,5 $ L,5,6 $ L,6,1 
AL,1,2,3,4,5,6 ! Определение площади 1 по линиям

! Определение отверстия - площади 2
K,7,0,-A
K,8,B,0
K,9,0,A

! Построение малого внутреннего эллипса
CSYS,100  ! Переход в систему координат с номером 100
L,7,8 $ L,8,9
CSYS,0
L,9,7
AL,7,8,9
ASBA,1,2 ! Вырезать из области 1 область 2

! Установка размеров элементов вблизи опорных точек
!KESIZE,ALL,DMESH
ESIZE,DMESH
KESIZE,7,DMESH1 $ KESIZE,8,DMESH1 $ KESIZE,9,DMESH1 
KESIZE,1,DMESH1 $ KESIZE,3,DMESH1 

AMESH,ALL ! Триангулировать область (3)
FINISH

/SOLU
ANTYPE,STAT          ! Решение стационарной задачи
! Граничное условие на линии (температура)
LSEL,S,line,,6	! Выбор линии L6
DL,ALL,,TEMP,T_INP	! Задать для выбранной линии TEMP=T_INP
LSEL,ALL
!DL,6,,TEMP,T_INP
! Граничное условие на узлах (конвективный теплообмен)
NSEL,S,LOC,Y,H-A-WL,H-A-WL	! Выбор всех узлов с координатой Y=H-A-WL (минимальное и максимальное значение равны)
SF,ALL,CONV,H_F,T_EXT ! Конвективный теплообмен в выбранных узлах
NSEL,ALL		! Вернуться к выбору всех узлов модели

ALLSEL,ALL ! ВЫБОР ВСЕХ СУЩНОСТЕЙ
SOLVE			! Решить СЛАУ МКЭ
FINISH

/POST1
!  Команды, управляющие форматом графического вывода
/SHOW,WIN32C
/TRIAD,OFF         ! Не показывать начала координат и осей
/PLOPTS,INFO,2     ! Использовать формат вывода Auto-legend для подписей
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,TITLE,OFF  ! Не показывать заголовок
/PLOPTS,MINM,ON
/PLOPTS,DATE,OFF   ! Не показывать дату
! Для показа распределений величин использовать 14 градаций уровней
/CONT,,14
! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PBC,TEMP,,1	!   Отображать граничные условия для температуры
/PSF,CONV,HCOEF,2 !   Отображать стрелками граничные условия с коэффициентом теплообмена
PLNSOL,TEMP		!   Показать поле температуры
!   Закомментированные команды для вывода теплового потока
!/PBC,TEMP,,0	!   Не показывать граничные условия для температуры
!/PSF,CONV,HCOEF,0 !  Не показывать граничные условия с коэффициентом теплообмена

SET,LAST ! СЧИТЫВАНИЕ РЕЗУЛЬТАТОВ ДЛЯ ПРОИЗВОДНЫХ РЕШЕНИЯ
PLNSOL,TF,SUM   ! Показать модуль вектора теплового потока