!  Th3S_rot.INP  - программа для ANSYS
!	Предметная область - теплофизика (Th)
!	Пространственная задача (3)
!	Линейный анализ (L)
!	Стационарная задача (S)
!
!	Расчет стационарного распространения тепла 
!	в оболочечной трехмерной конструкции
!
!	Геометрия области в пространстве получена 
!       из плоской области в форме буквы "R".
!
!       Вращение плоской области вокруг оси
!

/TITLE, Heat Flow in 3D shell
/PREP7

!  Все величины в системе Си

! Геометрические размеры тела в форме буквы "R"
HL=1.4 	 ! Высота 
WL=0.8   ! Ширина 
WWL=0.2 ! Ширина стенок буквы "R"
HAL=0.7 ! Дополнительный размер по высоте

T_INP1=90   ! Температура на левой части нижней границе
T_INP2=180   ! Температура на правой части нижней границе
T_EXT=0	! Температура окружающей среды для конвективных условий T_EXT=0
H_F=60	! Коэффициент конвективного теплообмена

MP,KXX,1,46.7 ! Коэффициент теплопроводности KXX=46.7 (Сталь)

PEL=(HAL/2)/(WL-WWL) ! Параметр эллиптичности для криволинейной части фигуры
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Эллиптическая система координат 11
CSYS,0	! Переход в основную декартову систему координат

! Определение основных опорных точек для внешней границы
K,1,0,0
K,2,WWL,0
K,3,WWL,HL-HAL-WWL
K,4,WL-WWL,0
K,5,WL,0
K,6,WWL,HL-HAL
K,7,WL,HL-HAL/2
K,8,WWL,HL
K,9,0,HL

 !   создание линий по точкам
L,1,2 $ L,2,3  $ L,3,4 $ L,4,5 $ L,5,6
CSYS,11    ! Переход в систему координат с номером 11
L,6,7 $ L,7,8
CSYS,0 ! Переход в основную декартову систему координат
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 ! Определение площади 1 по линиям

! Определение отверстия - площади 2
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL
K,11,WL-WWL,HL-HAL/2
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL
CSYS,11
L,10,11 $ L,11,12
CSYS,0
L,12,10
AL,10,11,12
ASBA,1,2 ! Вырезать из области 1 область 2

! Определение точек оси, отстоящей от плоской области слева на WWL
K,1001,-WWL,0
K,1002,-WWL,HL

! Создать объем вращением области 3 вокруг оси с точками 1001 и 1002 на 45 градусов
VROTAT,3,,,,,,1001,1002,45  
VDEL,ALL  !  Удалить только объем без поверхностей, линий и точек

! Параметры для триангуляции
DMESH=WWL/4

ET,1,SHELL57  ! Тип конечного элемента с номером 1 - четырехузловой оболочечный  SHELL57 
R,1,0.01   ! Набор констант для конечного элемента типа 1 (SHELL57) - толщина, равная здесь 0.01

! Установка размера конечного элемента 
esize,dmesh

AMESH,ALL ! Разбить все области на конечные элементы
FINISH

/SOLU
ANTYPE,STAT          ! Решение стационарной задачи
!  Определение новой системы координат - 
!  цилиндрической с осью Z'', совпадающей с осью поворота 
LOCAL,12,1,-WWL,0,0,,-90
CSYS,12
NSEL,S,LOC,Z,0	! Выбор всех узлов с координатой Z''=0
NSEL,R,LOC,X,WWL,2*WWL
D,ALL,TEMP,T_INP1	! Задать для всех выбранных узлов TEMP=T_INP1
NSEL,S,LOC,Z,0	! Выбор всех узлов с координатой Z''=0
NSEL,R,LOC,X,WL+WWL,WL
D,ALL,TEMP,T_INP2	! Задать для всех выбранных узлов TEMP=T_INP2
NSEL,S,LOC,Z,HL,HL	! Выбор всех узлов с координатой Z''=HL
NSEL,R,LOC,X,WWL,2*WWL
SF,ALL,CONV,H_F,T_EXT ! Конвективный теплообмен в выбранных узлах
NSEL,ALL		! Вернуться к выбору всех узлов модели
CSYS,0

SOLVE			! Решить СЛАУ МКЭ
FINISH