/TITLE, Plane Stress tension of an elastic plate with a hole
/PREP7
! В силу симметрии задачи рассматривается четверть пластинки
A=5	! Длина четверти пластинки
B=2	! Ширины четверти пластинки
R=0.25	! Радиус отверстия
H=0.1 	! Толщина пластинки
P=1e3 	! Величина растягивающей нагрузки  (кГ/см^2)
MP,EX,1,2e6 	! Модуль Юга EX=2*10+6  (кГ/см^2)
MP,NUXY,1,0.3	! Коэфициент Пуассона NUXY=0.3

! Сетка с плоскими линейными элементами (без промежуточных узлов)
!ET,1,PLANE182 ! Четырехузловой плоский КЭ PLANE183 для структурного анализа (четырехугольник без промежуточных узлов, плоское напряж. состояние)

! Сетка с плоскими квадратичными элементами (с промежуточными узлами)
ET,1,PLANE183 ! Восьмиузловой плоский КЭ PLANE183 для структурного анализа (четырехугольник с промежуточными узлами, плоское напряж. состояние)


K,1,0,0	! Определение граничных точек четверти пластинки
K,2,A,0
K,3,A,B
K,4,0,B
A,1,2,3,4	! Определение площади 1 по точкам
APLOT,1	! Показ площади 1

PCIRC,R	! Определение круга радиуса R с центром в центре рабочей плоскости

ASBA,1,2	! Вычитание из площади 1 площади 2 (круга)
APLOT,ALL	! Показ четверти пластины с отверстием

! Задание параметров для построения сетки конечных элементов
KESIZE,ALL,B/4
KESIZE,5,R/5
KESIZE,6,R/5

AMESH,ALL		! Построение сетки КЭ для площади 3
FINISH

/SOLU
ANTYPE,STAT          ! Решение статической задачи.
NSEL,S,LOC,X,A	! Выбор всех узлов с координатой X=A
SF,ALL,PRES,-P	! Для всех выбранных узлов поверхностная нагрузка PRES = -P
NSEL,ALL		! Вернуться к выбору всех узлов модели
DL,9,,SYMM		! Условие симметрии на линии 9 (линии с Y=0)
DL,10,,SYMM	! Условие симметрии на линии 10 (линии с X=0)

! ********************************************************
! Для плоского КЭ со степенями свободы UX, UY условия симметрии на линиях 9 и 10 здесь
! эквиваленты следующим командам
! УСЛОВИЯ СИММЕТРИИ НА ЛИНИЯХ 1/4 ПЛАСТИНЫ
!NSEL,S,LOC,X,0
!D,ALL,UX,0
!NSEL,S,LOC,Y,0
!D,ALL,UY,0
!NSEL,ALL
! ********************************************************

SOLVE			! Решить систему МКЭ
FINISH

save

/POST1
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,DATE,OFF   ! Не показывать дату

SET,last ! Считывание результатов

PLDISP,2 !(вывод деформированной сетки с недеформированным краем)

! Задержка для просмотра картинки (можно убрать)
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
PLNSOL,U,X	!  Вывод перемещений по оси X
*GET,UXMAX,PLNSOL,0,MAX ! UXMAX - максимальные перемещения по оси X

! Задержка для просмотра картинки (можно убрать)
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
PLNSOL,S,Y	! Вывод осевых напряжений (в декартовой системе координат)

! Задержка для просмотра картинки (можно убрать)
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
RSYS,1	! Переход в цилиндрическую систему координат для представления результатов
PLNSOL,S,Y	! Вывод тангенциальных напряжений (в цилиндрической системе координат)

! ********************************************************
! График тангенциальных напряжений T_Theta 
! вдоль пути на оси OX от точки (0,R) до точки (0,B)
! Задержка для просмотра предыдущей картинки
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
PATH,XX,2
PPATH,1,,0,R
PPATH,2,,0,B
PDEF,T_Theta,S,Y
PLPATH,T_Theta
!*******************************************************

RSYS,0	! Возврат в декартовую систему координат для представления результатов