/clear
/TITLE, Plane Stress tension of an elastic plate with a hole
/PREP7
! В силу симметрии задачи рассматривается четверть пластинки
A=5	! Длина пластинки
B=2	! Ширины  пластинки
R=0.25	! Радиус отверстия
H=0.1 	! Толщина пластинки
P=1e3 	! Величина растягивающей нагрузки  (кГ/см^2)
MP,EX,1,2e6 	! Модуль Юга EX=2*10+6  (кГ/см^2)
MP,NUXY,1,0.3	! Коэфициент Пуассона NUXY=0.3

DMESH=B/16
DMESHR=R/5

! Сетка с плоскими линейными элементами (без промежуточных узлов)
!ET,1,PLANE182 ! Четырехузловой плоский КЭ PLANE183 для структурного анализа (четырехугольник без промежуточных узлов, плоское напряж. состояние)

! Сетка с плоскими квадратичными элементами (с промежуточными узлами)
ET,1,PLANE183 ! Восьмиузловой плоский КЭ PLANE183 для структурного анализа (четырехугольник с промежуточными узлами, плоское напряж. состояние)


K,1,0,0	! Определение граничных точек четверти пластинки
K,2,A,0
K,3,A,B
K,4,0,B
A,1,2,3,4	! Определение площади 1 по точкам
APLOT,1	! Показ площади 1


!CYL4, XCENTER, YCENTER, RAD1, THETA1, RAD2, THETA2, DEPTH
CYL4,A/5,B/2,R/2
 
ASBA,1,2	! Вычитание из площади 1 площади 2 (круга)
APLOT,ALL	! Показ четверти пластины с отверстием

! Задание параметров для построения сетки конечных элементов
KESIZE,ALL,DMESH
ksel,s,,,5,8
KESIZE,all,DMESHR
ksel,all

AMESH,ALL		! Построение сетки КЭ для площади 3
FINISH

/SOLU
ANTYPE,STAT          ! Решение статической задачи

NSEL,S,LOC,X,0	! Выбор всех узлов с координатой X=0
! Жесткое закрепление
!D,ALL,UX,0 
!D,ALL,UY,0
D,ALL,ALL,0
NSEL,ALL

NSEL,S,LOC,X,A
SF,ALL,PRES,-P	! Для всех выбранных узлов СЖИМАЮЩАЯ нагрузка PRES = P
NSEL,ALL		! Вернуться к выбору всех узлов модели

SOLVE			! Решить систему МКЭ
FINISH

save

/POST1
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,DATE,OFF   ! Не показывать дату

SET,last ! Считывание результатов

PLDISP,2 !(вывод деформированной сетки с недеформированным краем)

PATH,XX,2
PPATH,1,,0,B/2
PPATH,2,,A/5-R/2,B/2
PDEF,SIGMA_XX,S,X
PLPATH,SIGMA_XX

PATH,XX,2
PPATH,1,,0,B/2
PPATH,2,,A/5-R/2,B/2
PDEF,SIGMA_YY,S,Y
PLPATH,SIGMA_YY

NSEL,S,LOC,X,A/5+R/2
NSEL,R,LOC,Y,B/2
*GET, NODMAX, NODE,,NUM,MAX
*GET, UX_VALUE, NODE, NODMAX, U, X
*GET, SIGMAXX_VALUE, NODE, NODMAX, S, X
NSEL,ALL