/TITLE, Stress tension strip with a hole (3D problem)
/PREP7

! В силу симметрии задачи рассматривается 1/8 часть  пластинки

A=5	! Длина 1/8 пластинки
B=2	! Ширина 1/8 пластинки
R=0.25	! Радиус отверстия
H=0.1 	! Толщина пластинки
P=1e3 	! Величина растягивающей нагрузки  (кГ/см^2)
MP,EX,1,2e6 	! Модуль Юга EX=2*10**6 (кГ/см^2)
MP,NUXY,1,0.3	! Коэффициент Пуассона NUXY=0.3

K,1,0,0	! Определение граничных точек 1/8 части пластинки
K,2,A,0
K,3,A,B
K,4,0,B
K,5,0,0,H/2
K,6,A,0,H/2
K,7,A,B,H/2
K,8,0,B,H/2

V,1,2,3,4,5,6,7,8 ! Объем (прямоугольный параллелепипед) по 8 вершинам	

CYLIND,R,,H/2 ! Цилиндр радиуса R и длины H/2     

VSBV,1,2	! Вычитание из объема 1 объема 2 (цилиндра)
VPLOT,ALL	! Показ одной восьмой части пластины с отверстием

! Задание параметров для построения сетки конечных элементов
KESIZE,ALL,B/4
KESIZE,10,R/5
KESIZE,13,R/5
KESIZE,12,R/5
KESIZE,14,R/5

!------------------! Тетраэдральная сетка
!ET,1,SOLID92	! 10-узловой тетраэдральный КЭ теории упругости
!Если использовать разбиение на тетраэдры, то вспомогательная плоская сетка не нужна
!VMESH,ALL ! Разбить все объемы на конечные элементы

!-----------! Гексаэдральная сетка с линейными элементами (без промежуточных узлов)
!et,1,SOLID45 ! Задать КЭ типа 1: основной элемент
! SOLID45 - 3D 8-узловой элемент для структурного анализа, степени свободы: ux,uy,uz (перемещения)
!ET,2,MESH200,6 ! Задать КЭ типа 2: вспомогательный четырехугольный 4-узловой (параметр 6) КЭ - только для геометрии сетки
!MSHAPE,0 ! Разбиение на четырехугольники

!-----------! Гексаэдральная сетка с квадратичными элементами (с промежуточными узлами)

et,1,SOLID95 ! Задать КЭ типа 1: основной элемент
!SOLID95 – 3D 20-узловой элемент для структурного анализа с промежуточными узлами, степени свободы: ux,uy,uz (перемещения)
ET,2,MESH200,7 ! Задать КЭ типа 2: вспомогательный четырехугольный 8-узловой (параметр 7) КЭ  - только для геометрии сетки
MSHAPE,0 ! Разбиение на четырехугольники
!--------------------------------------------------------

TYPE,2 ! Выбрать тип КЭ для разбиения плоской области (вспомогательный КЭ)
!Выбрать исходную двумерную область
ASEL,S,LOC,Z,0
!Разбить эту область вспомогательным элементом
AMESH,ALL
TYPE,1 ! Выбрать тип КЭ для разбиения объемов (основной КЭ)
! Протянуть разбиение плоской области вдоль объема и получить трехмерную сетку
VSWEEP,ALL
ASEL,ALL
FINISH

/SOLU
ANTYPE,STAT          ! Решение статической задачи.
NSEL,S,LOC,X,A		! Выбор всех узлов с координатой X=A
SF,ALL,PRES,-P	! Для всех выбранных узлов поверхностная нагрузка PRES = -P
NSEL,ALL	! Вернуться к выбору всех узлов модели
DA,11,SYMM
DA,12,SYMM
DA,14,SYMM

! ********************************************************
! Для трехмерного КЭ со степенями свободы UX, UY, UZ условия симметрии на областях 11, 12 и 14 здесь
! эквиваленты следующим командам
! УСЛОВИЯ СИММЕТРИИ НА ГРАНЯХ 1/8 ПЛАСТИНЫ
!NSEL,S,LOC,X,0       
!D,ALL,UX,0
!NSEL,S,LOC,Y,0
!D,ALL,UY,0
!NSEL,S,LOC,Z,0
!D,ALL,UZ,0
!NSEL,ALL	! Вернуться к выбору всех узлов модели

SOLVE			! Решить систему МКЭ
FINISH

/POST1
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,DATE,OFF   ! Не показывать дату

SET,last ! Считывание результатов

PLDISP,2 ! Деформированная форма (вывод деформированной сетки с недеформированным краем)

! Задержка для просмотра картинки (можно убрать)
PLNSOL,U,X	!  Вывод перемещений по оси X
*GET,UXMAX,PLNSOL,0,MAX ! UXMAX - максимальные перемещения по оси X

! Задержка для просмотра картинки (можно убрать)
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
PLNSOL,S,Y	! Вывод осевых напряжений (в декартовой системе координат)

! Задержка для просмотра картинки (можно убрать)
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
RSYS,1	! Переход в цилиндрическую систему координат для представления результатов
PLNSOL,S,Y	! Вывод тангенциальных напряжений (в цилиндрической системе координат)

! ********************************************************
! График тангенциальных напряжений T_Theta 
! вдоль пути на оси OX от точки (0,R) до точки (0,B)
! Задержка для просмотра предыдущей картинки
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
PATH,XX,2
PPATH,1,,0,R
PPATH,2,,0,B
PDEF,T_Theta,S,Y
PLPATH,T_Theta
!*******************************************************

RSYS,0	! Возврат в декартовую систему координат для представления результатов