/CLEAR
/TITLE, Stress tension strip with a hole (3D problem)
/PREP7

! В силу симметрии задачи рассматривается 1/8 часть  пластинки

A=5	! Длина пластинки
B=2	! Ширина  пластинки
R=0.25	! Радиус отверстия
H=0.1 	! Толщина пластинки
P=1e3 	! Величина растягивающей нагрузки  (кГ/см^2)
MP,EX,1,2e6 	! Модуль Юга EX=2*10**6 (кГ/см^2)
MP,NUXY,1,0.3	! Коэффициент Пуассона NUXY=0.3

!-------Изменение толщины пластины----------------------------
N=10
H=N*H
!-------------------------------------------------------------
DMESH=B/16
DMESHR=R/5
DMESHH=H/N


K,1,0,0	! Определение граничных точек 1/8 части пластинки
K,2,A,0
K,3,A,B
K,4,0,B
K,5,0,0,H
K,6,A,0,H
K,7,A,B,H
K,8,0,B,H

V,1,2,3,4,5,6,7,8 ! Объем (прямоугольный параллелепипед) по 8 вершинам	

!CYL4, XCENTER, YCENTER, RAD1, THETA1, RAD2, THETA2, DEPTH
CYL4,A/5,B/2,R/2,,,,H
 
VSBV,1,2	! Вычитание из объема 1 объема 2 (цилиндра)
VPLOT,ALL	! Показ одной восьмой части пластины с отверстием

! Задание параметров для построения сетки конечных элементов
KESIZE,ALL,DMESH
ksel,s,,,9,12
KESIZE,all,DMESHR

!-----------! Гексаэдральная сетка с линейными элементами (без промежуточных узлов)
ET,1,SOLID185 ! Задать КЭ типа 1: основной элемент SOLID185
! SOLID185 - 3D 8-узловой элемент для структурного анализа, степени свободы: ux,uy,uz (перемещения)
ET,2,MESH200,6 ! Задать КЭ типа 2: вспомогательный четырехугольный 4-узловой (параметр 6) КЭ - только для геометрии сетки
MSHAPE,0 ! Разбиение на четырехугольники


TYPE,2 ! Выбрать тип КЭ для разбиения плоской области (вспомогательный КЭ)
!Выбрать исходную двумерную область
ASEL,S,LOC,Z,0
!Разбить эту область вспомогательным элементом
AMESH,ALL
TYPE,1 ! Выбрать тип КЭ для разбиения объемов (основной КЭ)

LESIZE,9,DMESHH

! Протянуть разбиение плоской области вдоль объема и получить трехмерную сетку
VSWEEP,ALL
ASEL,ALL
FINISH

/SOLU
ANTYPE,STAT          ! Решение статической задачи.
ASEL,S,LOC,X,A		! Выбор всех ОБЛАСТЕЙ с координатой X=A
NSLA,S,1
SF,ALL,PRES,-P	! Для всех выбранных узлов поверхностная нагрузка PRES = -P
NSEL,ALL	! Вернуться к выбору всех узлов модели
ASEL,S,LOC,X,0	
DA,ALL,ALL,0
ASEL,ALL

SOLVE			! Решить систему МКЭ
FINISH

/POST1
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,DATE,OFF   ! Не показывать дату

SET,last ! Считывание результатов

PLDISP,2 ! Деформированная форма (вывод деформированной сетки с недеформированным краем)


NSEL,S,LOC,X,A/5+R/2
NSEL,R,LOC,Y,B/2
NSEL,R,LOC,Z,H/2
*GET, NODMAX, NODE,,NUM,MAX
*GET, UX_VALUE, NODE, NODMAX, U, X
NSEL,ALL