!     Файл    FE_Mod_CP_2.inp
!     Д В У М Е Р Н А Я    З А Д А Ч А 
!     Т Е Р М О У П Р У Г О Е     Т Е Л О
!     Нестационарная задача

! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PREP7
!  Все величины в системе Си

TES1=10   !  значение времени для окончания первого шага
TES2=120   !  значение времени для окончания второго шага
!  подшаги по времени для временных шагов
DT1=1   !  значение для шага 1   
DT2=2   !  значение для шага 2

! Условия для "температурного" анализа
T_INP1=0   ! Температура на нижней границе
T_INP2=90   ! Температура на правой верхней границе (на шаге 1)
T_EXT=0	! Температура окружающей среды для конвективных условий 
H_F=60	! Коэффициент конвективного теплообмена

! Разность температур от нуля до абсолютного нуля 
TOFFST, 273
! При TOFFST=0 тепловое уравнение есть уравнение теплопроводности
! TOFFST, 0   

!  Материальные свойства  (сталь)
E1=2.1e11 ! Модуль Юнга
NU1=0.29 ! Коэффициент Пуассона
RHO1=7.8e3 ! Плотность
K1=46.7 ! Коэффициент теплопроводности
C1=462 ! Удельная теплоемкость 
ALPH1=1.51e-05 ! Коэффициент температурного расширения

MP,EX,1,E1  
MP,DENS,1,RHO1 
MP,NUXY,1,NU1
MP,KXX,1,K1
MP,C,1,C1  
MP,ALPX,1,ALPH1

! Команды для анализа возможности не учета 
! динамических слагаемых в уравнениях движения 
! KAPPA=1e-6 
! MP,DENS,1,RHO1*KAPPA 
! MP,C,1,C1/KAPPA

ET,1,PLANE223,11,,2  ! четырехугольный КЭ  с 8 узлами, степени свободы UX, UY, TEMP, плоская деформация

! Геометрические размеры тела в форме буквы "R"
HL=0.14 	  ! Высота 
WL=0.08    ! Ширина 
WWL=0.02 ! Ширина стенок буквы "R"
HAL=0.07   ! Дополнительный размер по высоте

! Параметры для триангуляции
DMESH=WWL/4

PEL=(HAL/2)/(WL-WWL) ! Параметр эллиптичности для криволинейной части 
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Эллиптическая система координат с номером 11
CSYS,0	! Переход в основную декартову систему координат

! Создание геометрии фигуры
! Внешняя часть - область 1
K,1,0,0
K,2,WWL,0
K,3,WWL,HL-HAL-WWL
K,4,WL-WWL,0
K,5,WL,0
K,6,WWL,HL-HAL
K,7,WL,HL-HAL/2
K,8,WWL,HL
K,9,0,HL
L,1,2 $ L,2,3  $ L,3,4 $ L,4,5 $ L,5,6

CSYS,11    
L,6,7 $ L,7,8
CSYS,0
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 

! Отверстие - область 2
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL
K,11,WL-WWL,HL-HAL/2
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL
CSYS,11
L,10,11 $ L,11,12
CSYS,0
L,12,10
AL,10,11,12
ASBA,1,2 ! Вырезать из области 1 область 2

! Установка размера конечного элемента 
ESIZE,DMESH

AMESH,ALL

!  Условия жесткого закрепления
NSEL,S,LOC,Y,0    ! Выбор узлов внизу (по оси Y)
D,ALL,UX,0
D,ALL,UY,0
NSEL,ALL	! Вернуться к выбору всех узлов модели

!  Выбор узлов для мониторинга результатов
!  Узел N1_MON - в верхней части фигуры
!  Y=HL, X=WWL
NSEL,S,LOC,Y,HL,HL
NSEL,R,LOC,X,WWL
*GET,N1_MON,NODE,,NUM,MIN
!  Узел N2_MON - ниже по X=WWL
NSEL,S,LOC,Y,HL-HAL/2-(WL-2*WWL)*PEL
NSEL,R,LOC,X,WWL
*GET,N2_MON,NODE,,NUM,MIN
NSEL,ALL

FINISH

! Решение связанной задачи термоупругости
/SOLU
ANTYPE,TRANS          ! Решение нестационарной задачи
KBC,0   ! Линейный рост внешних воздействий 

!  Коэффициент затухания в схеме интегрирования по времени
!TINTP,0.005  ! TINTP=0.005 - по умолчанию
TIME,TES1     ! Время окончания шага 1
DELTIM,DT1  ! Подшаг по времени для шага 1

NSEL,S,LOC,Y,0    ! Выбор узлов внизу (по оси Y)
D,ALL,TEMP,T_INP1	! Задать для всех выбранных узлов TEMP=T_INP1

NSEL,S,LOC,Y,HL,HL   ! Выбор узлов  вверху (по оси Y)
NSEL,R,LOC,X,0,WWL
D,ALL,TEMP,T_INP2	! Задать для всех выбранных узлов TEMP=T_INP2
NSEL,ALL

OUTRES,BASIC,ALL
SOLVE	

! Шаг 2
TIME,TES2
DELTIM,DT2
KBC,1  ! Значения внешних воздействий постоянны 
NSEL,S,LOC,Y,HL,HL   ! Выбор узлов  вверху (по оси Y)
NSEL,R,LOC,X,0,WWL
DDEL,ALL,TEMP     ! Удаление условий TEMP=T_INP2
SF,ALL,CONV,H_F,T_EXT ! Конвективный теплообмен в выбранных узлах
NSEL,ALL
 
SOLVE
SAVE
FINISH

/POST26
/SHOW,WIN32C
/TRIAD,OFF         ! Не показывать начала координат и осей
/PLOPTS,INFO,2     ! Использовать формат вывода Auto-legend для подписей
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом ви-де
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,DATE,OFF   ! Не показывать дату
/COLOR,CURVE,WHIT,1,6  ! Цвет графиков - белый (черный при инвер-тации)
/COLOR,GRID,WHIT   ! Цвет сетки - белый (черный при инвертации)
/GMARKER,1,2,3    ! Для кривой 1 метка 2 - квадратики, на каждом 3-ем значении
/GMARKER,2,4,3    ! Для кривой 2 метка 4 - крестики, на каждом 3-ем значении
/GRID,1         !   Сетка по X и Y (полная сетка)

/XRANG,0,TES2
/AXLAB,Y,Temperature (degree)  ! Подпись к оси Y
/AXLAB,X,Time (sec)   ! Подпись к оси Y
NSOL,2,N1_MON,TEMP,,TEMP1  ! Переменная 2 - температура в узле N1_MON
NSOL,3,N2_MON,TEMP,,TEMP2

NSOL,4,N1_MON,U,Y,UY1  ! Переменная 4 - перемещение UY в узле N1_MON
NSOL,5,N2_MON,U,Y,UY2

PLVAR,2,3  ! Построение графиков переменных 2, 3 от времени (пере-менной 1)

! Снять комментарии для вывода UY в контрольных узлах
! /AXLAB,Y,UY (m)
! PLVAR,4,5