!     Файл    FE_Mod_CP_ha.inp
!     П Л О С К А Я    З А Д А Ч А 
!     К О Л Е Б А Н И Я   С О С Т А В Н О Г О   
!     К О Л Ь Ц А  (Ц И Л И Н Д Р А)  
!     В   А К У С Т И Ч Е С К О Й    С Р Е Д Е
!      
!     Расчет установившихся колебаний тела с жидкостью
!     Бесконечные элементы FLUID129

! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PREP7
F_R='FE_Mod_CP_ha_4_SM1'        ! имя файлов для вывода результатов

! Параметры для геометрических размеров (все - в системе СИ)
R1=0.25  ! внутренний радиус кольца
R2=0.26  ! серединный радиус кольца
R3=0.27  ! внешний радиус кольца
KRA=4     ! коэффициент для вычисления радиуса RA
RA=KRA*R3  ! радиус для внешний границы жидкости

FP=100 ! Значение силы
NFREQ=100   !  число выводимых частот
FBEG=100  !  начальное значение диапазона частот
FEND=150 !  конечное значение диапазона частот

! Материальные свойства
!  Материальные константы стали
RO1=7.86e3  ! плотность
E1=2e11     ! модуль Юнга
NU1=0.29    ! коэффициент Пуассона
!  Материальные константы меди
RO2=8.9e3
E2=1.2e11
NU2=0.33
!  Материальные константы жидкости
ROA=1030
CA=1560
AD=1

MP,DENS,1,RO1   !  плотность среды 1
MP,EX,1,E1           !  модуль Юнга среды 1
MP,NUXY,1,NU1   !  коэффициент Пуассона среды 1
    !
MP,DENS,2,RO2   !  плотность среды 2
MP,EX,2,E2           !  модуль Юнга среды 2
MP,NUXY,2,NU2   !  коэффициент Пуассона среды 2
   !
MP,DENS,3,ROA   !  плотность акустической среды
MP,SONC,3,CA      !  скорость звука в акустической среде
MP,MU,3,AD          !  коэффициент поглощения на импедансной границе

ET,1,PLANE42,,,2  ! Упругий КЭ с 4 узлами, плоская деформация
ET,2,FLUID29,,1    ! Акустический КЭ с 4 узлами,  без UX & UY
ET,3,FLUID29        ! Акустический КЭ с 4 узлами,  с UX & UY
ET,4,FLUID129      ! Акустический КЭ для бесконечных границ
R,4,RA ! Радиус бесконечной границы для КЭ FLUID129

! Параметры конечно-элементной сетки
SM=1.00  ! масштабный множитель (scaling multiplier)
HDIV=2*SM  ! Кол-во КЭ по толщине (для одного материала)
TDIV=32*SM ! Кол-во КЭ по окружному направлению 
HADIV=32*SM ! Кол-во КЭ по радиальному направлению для акустич. среды
SPACE=3 ! Множитель для увеличения длины акуст. КЭ по радиальному направлению

/OUTPUT,F_R,res
*VWRITE
(1X,'   HARMONIC  ANALYSIS (Plane42, Fluid29)')
*VWRITE,KRA
(1X,'   RA/R3= ',F4.0)
*VWRITE,NFREQ
(1X,'   NFREQ= ',F4.0)
*VWRITE,HDIV,TDIV,HADIV
(1X,'   HDIV= ',F4.0,'   TDIV= ',F4.0,'   HADIV= ',F4.0)
/OUTPUT

! Создание геометрии модели
CSYS,1 ! Переход в цилиндрическую систему координат
K,1,R1 $ K,2,R2 $ K,3,R3  
K,4,R3,90 $ K,5,R2,90 $ K,6,R1,90 
L,6,1 $ L,1,2 $ L,2,5 $ L,5,6 $ L,2,3 $ L,3,4 $ L,4,5
A,1,2,5,6 $ A,2,3,4,5
K,7,RA $ K,8,RA,90
L,3,7 $ L,7,8 $ L,8,4
A,3,7,8,4
CSYS,0 ! Возврат в декартовую систему координат

! Разбиение линий
LESIZE,1,,,TDIV $ LESIZE,3,,,TDIV $ LESIZE,6,,,TDIV
LESIZE,2,,,HDIV $ LESIZE,5,,,HDIV
LESIZE,4,,,HDIV $ LESIZE,7,,,HDIV
LESIZE,9,,,TDIV
LESIZE,8,,,HADIV,SPACE
LESIZE,10,,,HADIV,1/SPACE
MSHKEY,1
MSHAPE,0,2D 
ASEL,S,AREA,,2   ! Выделяем новое множество областей - область 2
AATT,2,,1  ! Ассоциируем с выделенной областью
            ! атрибуты: MAT=2,  TYPE=1
ASEL,S,AREA,,3   
AATT,3,,2  ! Ассоциируем с выделенной областью
            ! атрибуты: MAT=3,  TYPE=2
ASEL,ALL  ! Возврат к выбору всех областей
AMESH,ALL

! Изменение акуст. КЭ, граничащих с кольцом, на тип 3
LSEL,S,LINE,,6 ! Выбор линии 6 - границы кольца и акустич. среды
NSLL,S,1 ! Выбор узлов на выбранных линиях
ESLN,S,0 ! Выбор КЭ, имеющих выбранные узлы
ESEL,U,TYPE,,1 ! Исключение из выбранного множества КЭ с типом 1
EMODIF,ALL,TYPE,3
ALLSEL

! Установка флага контакта твердого тела с акустич. средой для акуст. КЭ
CSYS,1
NSEL,S,LOC,X,R3   ! Выбор узлов на границе твердого и жидкого тел
ESLN ! Выбор КЭ. имеющих выбранные узлы
ESEL,R,TYPE,,3  ! Выбор из них КЭ, имеющих TYPE=3
SF,ALL,FSI    ! Установка флага для узлов контакта FSI
NSEL,ALL
ESEL,ALL
CSYS,0

FINISH

/SOLU
ANTYPE,HARMIC   ! Установившиеся колебания
HROPT,FULL
HARFRQ,FBEG,FEND
NSUBST,NFREQ
KBC,1

! Условия симметрии
LSEL,S,LOC,Y,0
LSEL,A,LOC,X,0
DL,ALL,,SYMM
LSEL,ALL

CSYS,1
KSEL,S,LOC,X,R1
KSEL,R,LOC,Y,0
FK,ALL,FX,-FP/2  ! Делим FP на 2, т.к. рассматривается часть модели 
KSEL,ALL
CSYS,0

! Определение бесконечных элементов FLUID129
CSYS,1
NSEL,S,LOC,X,RA   ! Выбор узлов на импедансной границе
TYPE,4 $ REAL,4 $ MAT,3
ESURF
ESEL,ALL
NSEL,ALL
CSYS,0

OUTRES,BASIC,ALL
SOLVE 
SAVE
FINISH

/POST26
/SHOW,WIN32C
/TRIAD,OFF         ! Не показывать начала координат и осей
/PLOPTS,INFO,2     ! Использовать формат вывода Auto-legend для подписей
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   ! Логотип ANSYS не показывать в графическом виде
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/PLOPTS,DATE,OFF   ! Не показывать дату

/COLOR,CURVE,WHIT,1,6
/COLOR,GRID,WHIT
/GRID,1

CSYS,1
NSEL,S,LOC,X,R3     
NSEL,R,LOC,Y,90
! Узел с номером N_RES1 - точка (0,R3) в дек. сист. коорд.
*GET,N_RES1,NODE,,NUM,MIN 
NSEL,S,LOC,X,RA     
NSEL,R,LOC,Y,90
! Узел с номером N_RES2 - точка (0,RA) в дек. сист. коорд.
*GET,N_RES2,NODE,,NUM,MIN 
NSEL,ALL
CSYS,0

/XRANG,FBEG,FEND
/AXLAB,X,Frequency (Hz)
/AXLAB,Y,Displacement UY (m)
NSOL,2,N_RES1,UY
ABS,3,2,,ABSUY
*GET,FRES,VARI,3,EXTREM,TMAX ! Определение рез. частоты

/OUTPUT,F_r,res,,append
*VWRITE,FRES
(1X,'   FRES= ',E12.5)
PRVAR,2
/OUTPUT
PLCPLX,2 ! Вещественная часть UY
PLVAR,2

! PLVAR,3 ! Амплитуда или модуль  UY

! Команды для вывода давления в той же точке
! NSOL,4,N_RES1,PRES
! /AXLAB,Y,Acoustic pressure PRES (Pa)
! PLVAR,4