!     Файл    FE_Mod_CP_mod.inp
!     П Л О С К А Я    З А Д А Ч А 
!     К О Л Е Б А Н И Я   С О С Т А В Н О Г О   
!     К О Л Ь Ц А  (Ц И Л И Н Д Р А)   
!      
!     Расчет собственных частот тела без жидкости

! Инвертирование фона с черного на белый
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PREP7
F_R='FE_Mod_CP_mod'        ! имя файлов для вывода результатов

! Параметры для геометрических размеров (все - в системе СИ)
R1=0.25  ! внутренний радиус кольца
R2=0.26  ! серединный радиус кольца
R3=0.27  ! внешний радиус кольца

NFREQ=4   !  число выводимых частот
FBEG=0.1  !  начальное значение диапазона частот
FEND=1e10 !  конечное значение диапазона частот

! Материальные свойства тела
!  Материальные константы стали
RO1=7.86e3  ! плотность
E1=2e11     ! модуль Юнга
NU1=0.29    ! коэффициент Пуассона
!  Материальные константы меди
RO2=8.9e3
E2=1.2e11
NU2=0.33

MP,DENS,1,RO1       !  плотность среды 1
MP,EX,1,E1          !  модуль Юнга среды 1
MP,NUXY,1,NU1       !  коэффициент Пуассона среды 1
    !
MP,DENS,2,RO2       !  плотность среды 2
MP,EX,2,E2          !  модуль Юнга среды 2
MP,NUXY,2,NU2       !  коэффициент Пуассона среды 2

ET,1,PLANE42,,,2  ! Упругий КЭ с 4 узлами, плоская деформация

! Параметры конечно-элементной сетки
SM=1.00  ! масштабный множитель (scaling multiplier)
HDIV=2*SM  ! Кол-во КЭ по толщине (для одного материала)
TDIV=32*SM ! Кол-во КЭ по окружному направлению 

/OUTPUT,F_R,res
*VWRITE
(1X,'   MODAL ANALYSIS (Block Lanczos, Plane42)')
*VWRITE,NFREQ
(1X,'   NFREQ= ',F4.0)
*VWRITE,HDIV,TDIV
(1X,'   HDIV= ',F4.0,'   TDIV= ',F4.0)
/OUTPUT
*DIM,FR,ARRAY,NFREQ  ! массив для собственных частот

! Создание геометрии модели
CSYS,1 ! Переход в цилиндрическую систему координат
K,1,R1 $ K,2,R2 $ K,3,R3  
K,4,R3,90 $ K,5,R2,90 $ K,6,R1,90 
L,6,1 $ L,1,2 $ L,2,5 $ L,5,6 $ L,2,3 $ L,3,4 $ L,4,5
A,1,2,5,6
A,2,3,4,5
CSYS,0 ! Возврат в декартовую систему координат

! Разбиение линий
LESIZE,1,,,TDIV $ LESIZE,3,,,TDIV $ LESIZE,6,,,TDIV
LESIZE,2,,,HDIV $ LESIZE,5,,,HDIV
LESIZE,4,,,HDIV $ LESIZE,7,,,HDIV
MSHKEY,1
MSHAPE,0,2D 
ASEL,S,AREA,,2   ! Выделяем новое множество областей - область 2
AATT,2,,1  ! Ассоциируем с выделенной областью
            ! атрибуты: MAT=2,  TYPE=1
ASEL,ALL  ! Возврат к выбору всех областей
AMESH,ALL
FINISH

/SOLU
ANTYPE,MODA  ! Модальный анализ
! Блочный метод Ланцоша
! Число частот NFREQ в интервале FBEG,FEND
MODOPT,LANB,NFREQ,FBEG,FEND 

! Условия симметрии
LSEL,S,LOC,Y,0
LSEL,A,LOC,X,0
DL,ALL,,SYMM
LSEL,ALL

SOLVE 
FINISH

/POST1
 ! Вывод таблицы резонансных частот в файл
*DO,I,1,NFREQ
  SET,,I
  *GET,FR(I),MODE,I,FREQ
  FRI=FR(I)
  /OUTPUT,F_r,res,,append
  *VWRITE,I,FRI
  (1X,F4.0,'   ',E12.5)
  /OUTPUT
*ENDDO

! Вывод картинок форм (мод) колебаний
/PNUM,MAT,1	! Нумеровать элементы по материальным свойствам
/NUMBER,1	! Номера отражать только цветом 
/TRIAD,OFF	!  Не показывать начало системы координат
/PLOPTS,LOGO,OFF ! Отключить вывод графической картинки ANSYS
/PLOPTS,DATE,OFF	! Не показывать дату
/PLOPTS,FRAME,OFF  ! Не показывать рамку
/WINDOW,1,LTOP       ! Окно 1 - слева вверху
SET,,1  ! считываются данные по первой моде колебаний
PLDISP,2 !  показать моду колебаний вместе с исходной формой 
/WINDOW,1,OFF        ! Сделать окно 1 пассивным
/NOERASE             ! Не очищать содержимое окон
/WINDOW,2,RTOP       ! Окно 2 - справа вверху
SET,,2  ! считываются данные по второй моде колебаний
PLDISP,2
/WINDOW,2,OFF
/WINDOW,3,LBOT       ! Окно 3 - слева внизу
SET,,3  ! считываются данные по третьей моде колебаний
PLDISP,2
/WINDOW,3,OFF
/WINDOW,4,RBOT       ! Окно 4 - справа внизу
SET,,4  ! считываются данные по четвертой моде колебаний
PLDISP,2

! Возврат к обычным оконным режимам
/WINDOW,1,ON 
/WINDOW,1,FULL
/WINDOW,4,OFF

! Надо выполнить данную команду (без !) для очистки содержимого окна
!ERASE