! ********************************************************************
!
!  Данная программа входит в набор программ SMs1.inp - SMs10.inp 
!                          учебного пособия:
!   Наседкин А.В. "Конечно-элементное моделирование на основе ANSYS.
!   Программы решения статических задач сопротивления материалов
!   c вариантами индивидуальных заданий" //
!   Ростов-на-Дону: УПЛ РГУ, 1998. 44 с. 
!   
!  Автор программ - Наседкин Андрей Викторович,
!   Ростовский госуниверситет, кафедра математического моделирования,
!   nasedkin@ms.math.rsu.ru или nasedkin@ns.math.rsu.ru
!
! ********************************************************************
/BATCH
/COM,                Файл SMs1.inp
/COM,            Пример расчета плоской фермы
/COM, (Мещерский И.В. Сборник задач по теоретической механике.
/COM,  М.: Наука, 1986. Задача 4.67 (5.7))
F_R='SMs1'       ! Имя файла для вывода результатов
/PREP7
ET,1,LINK1       ! Стержневой КЭ LINK1
R,1,1e-4  ! Плошадь поперечного сечения стержней AREA=1e-4 (произвольная)
MP,EX,1,2E11 ! Модуль Юнга материалов стержней EX=2e11 (произвольный)
S3=SQRT(3)
N,1,0,0       ! Определяем узлы по координатам на плоскости
N,2,2,0
N,3,4,0
N,4,2.5,S3/2
N,5,1,S3
E,1,2         ! Определяем элементы текущего типа TYPE=1 (LINK1)
E,2,3         !  с текущими наборами констант REAL=1
E,3,4         !  и материальных свойств MAT=1
E,4,5         !  по номерам граничных узлов
E,5,1
E,5,2
E,2,4
FINISH
/SOLU
ANTYPE,STATIC     ! Статический анализ
!  Определяем шарнирные опоры в узлах
D,1,UY,0,,3,2     ! UY=0 в узлах 1 и 3 
D,3,UX            ! UX=0 в узле 3
!  Задаем силы в узлах
F,1,FY,-1E3,,3,2  ! FY=-1e3 в узлах 1 и 3
F,4,FY,-2E3,,5    ! FY=-2e3 в узлах 4 и 5
SOLVE             ! решаем СЛАУ
FINISH
/POST1
/OUTPUT,F_R,res   ! Направляем вывод в файл <F_R>.res
PRRSOL            ! Печатаем опорные реакции
PRESOL,SMISC,1    ! Печатаем усилия в стержнях
/OUTPUT
FINISH
/EXIT