/BATCH

!	Тестовая задача, иллюстрирующая технику
!	решения задачи на собственные частоты (Модальный анализ)
!	для системы уравнений теории упругости
!	(плоское напряженное состояние).

/TITLE, Modal Analysis
F_R='Mod_Ans'        ! имя файлов для вывода результатов
/SHOW,F_R,grph

PI=3.1416  ! Число PI

NFREQ=7        !  число выводимых частот и мод колебаний

/PREP7

HL=0.4 ! Толщина буквы

! Параметры для триангуляции
DIV=2
DMESH=HL/DIV
DMESH1=DMESH/2

/OUTPUT,F_R,res
*VWRITE
(1X,'   MODE-FREQUENCY ANALYSIS (SUBSP, PLANE2)')

*VWRITE,NFREQ
(1X,'    NFREQ= ',F4.0)
/COM,   i    ! Frequency (ANSYS)
/OUTPUT

*DIM,FR,ARRAY,NFREQ  ! массив для собственных частот

!  Материальные константы стали
RO1=7.86e3  ! плотность
E1=2e11     ! модуль Юнга
NU1=0.29    ! коэффициент Пуассона

!  Материальные константы меди
RO2=8.9e3
E2=1.2e11
NU2=0.33
    
MP,DENS,1,RO1       !  плотность среды 1
MP,EX,1,E1          !  модуль Юнга среды 1
MP,NUXY,1,NU1       !  коэффициент Пуассона среды 1
    !
MP,DENS,2,RO2       !  плотность среды 2
MP,EX,2,E2          !  модуль Юнга среды 2
MP,NUXY,2,NU2       !  коэффициент Пуассона среды 2
    
ET,1,PLANE182    ! КЭ PLANE2

LOCAL,11,1,0,0,,,,,2/3 ! Эллиптическая система координат 11
LOCAL,12,1,0,0,,,,,(1-HL)/(1.5-HL) ! Эллиптич. сист. коорд. 12
CSYS,0	! Переход в основную декартову систему координат
! Определение основных точек
K,1,0,-1
K,2,1.5,0
K,3,0,1
K,4,0,2.5
K,5,-HL,2.5
K,6,-HL,-1
K,7,-HL,1

CSYS,11
L,1,2 $ L,2,3
CSYS,0
L,3,7 $ L,7,6 $ L,6,1 
AL,1,2,3,4,5 ! Определение площади 1 по линиям al,all
L,7,5 $ L,5,4 $ L,4,3
AL,3,6,7,8   ! Определение площади 2 по линиям

! Определение отверстия - площади 3
K,8,0,-1+HL
K,9,1.5-HL,0
K,10,0,1-HL
CSYS,12
L,8,9 $ L,9,10
CSYS,0
L,10,8
AL,9,10,11
ASBA,1,3 ! Вырезать из области 1 область 3

! Установка размеров элементов вблизи опорных точек
KESIZE,ALL,DMESH
KESIZE,1,DMESH1 $ KESIZE,3,DMESH1 
KESIZE,8,DMESH1 $ KESIZE,10,DMESH1
LESIZE,3,,,DIV  ! Линию 3 разбить на DIV частей

ASEL,S,AREA,,4    ! Выделем новое множество площадей - площадь 4
AATT,1,,1  ! Ассоциируем с выделенным множеством площадей
            ! атрибуты: MAT=1,  TYPE=1
ASEL,S,AREA,,2    ! Выделем новое множество площадей - площадь 2
AATT,2,,1   ! атрибуты: MAT=2,  TYPE=1
ASEL,ALL  ! Возврат к выботу всех площадей

AMESH,ALL ! Триангулировать все области (2 и 4)

*GET,EL_MAX,ELEM,,COUNT  ! EL_MAX - число элементов
*GET,ND_MAX,NODE,,COUNT  ! ND_MAX - число узлов
/OUTPUT,F_r,res,,append
*VWRITE,EL_MAX,ND_MAX
(1X,' NEL_MAX=',F6.0,' NND_MAX=',F6.0)
/OUTPUT

SAVE
FINISH

/SOLU
ANTYPE,MODA          ! Решение задач на собственные значения.
MODOPT,SUBSP,NFREQ ! Метод решения - SUBSPACE,
                   ! число частот и мод - NFREQ
RIGID,ALL ! Задание мод колебаний твердого тела



OUTRES,BASIC,ALL ! Запись основных результатов для всех найденных частот
SOLVE
SAVE
FINISH

/POST1
 ! Вывод таблицы резонансных частот и картинок мод колебаний
*DO,I,1,NFREQ
  SET,,I
  *GET,FR(I),MODE,I,FREQ
  FRI=FR(I)
  /OUTPUT,F_r,res,,append
  *VWRITE,I,FRI
  (1X,F4.0,'   ',E12.5)
  /OUTPUT
  PLDISP,1
*ENDDO
FINISH

!/EXIT