{ St2LM_2.pde }

  { **************************************************************
	
	Тестовая задача № 2
	на собственные частоты (Модальный анализ)
	для системы уравнений теории упругости
	(плоское напряженное состояние).

	Геометрия области --- тело в форме двутаврового профиля.

	Нижняя часть области выполнена из стального материала,
	верхняя --- из медного.
	
	Нижняя граница жестко защемлена,
	остальная часть границы свободна от напряжений.

    *************************************************************** }

  title "Free vibrations analysis"

  select
    modes =4 	{число собственных значений и форм}
    errlim=1e-5

  Variables
    U                   { U и V - переменные }
    V


  definitions
    {геометрические параметры - в системе СИ}
    h=2e-2      {толщина}
    b=16e-2	{полувысота}
    l=5e-2	{полуширина планки}
    nu = 0.29	{ коэффициент Пуассона для стали}
    E  = 2e11 	{ модуль Юнга для стали }
    rho = 7.86e3   {плотность стали}
    mu  = E/2/(1+nu)	{модуль сдвига}
    lambdaL =  2*mu*nu/(1-2*nu)   {коэфф. Ламе}
	{коэфф. Ламе для плоского напряженного состояния }
    lambdaz = 2*mu*lambdaL/(lambdaL+2*mu)
    Sxx = dx(U)		{осевые деформации Sxx}
    Syy = dy(V)		{осевые деформации Syy}
    Sxy = (dy(U)+dx(V))/2	{сдвиговые деформации Sxy}
    Txx= lambdaz*(Sxx+Syy)+2*mu*Sxx        {напряжения Txx}
    Tyy= lambdaz*(Sxx+Syy)+2*mu*Syy       {напряжения Tуу}
    Txy=2*mu*Sxy			 {напряжения Txy}
    Scal=0.2*globalmax(magnitude(x,y))/globalmax(magnitude(u,v))
    Freq=sqrt(lambda)/(2*pi) {Частота f в Гц}

  equations
	{ дифференциальные уравнения колебаний
                          для плоской задачи теории упругости}
   u:  dx(Txx) + dy(Txy) + lambda*rho*U  = 0
   v:  dx(Txy) + dy(Tyy) + lambda*rho*V  = 0


constraints             { раскомментировать, если границы тела свободны от напряжений  }
   integral(u) = 0
   integral(v) = 0
   integral(dx(v)-dy(u)) = 0


  boundaries               { геометрия области и граничные условия }
     Region 1        {область 1 --- верхняя стальная часть}
	start (h/2,0)
	natural(U)=0 natural(V)=0    {граница свободна от напряжений}
	line to (h/2,b-h) to (l,b-h) to (l,b)  to (-l,b)
	line to (-l,b-h) to (-h/2,b-h) to (-h/2,0) to close

     Region 2         {область 2 с другими материальными свойствами}
	{материальные свойства меди}
	nu=0.33  E=1.2e11  rho=8.9e3
	start (h/2,0)
	natural(U)=0 natural(V)=0    {граница свободна от напряжений}
	line to (h/2,-b+h) to (l,-b+h) to (l,-b)
	value(U)=0  value(V)=0   {защемление части границы}
	line to (-l,-b)
	natural(U)=0 natural(V)=0
	line to (-l,-b+h) to (-h/2,-b+h) to (-h/2,0) to close


  monitors
    grid(x+Scal*U,y+Scal*V)  as "Eigen mode"
        report Freq as "Eigen frequency"

  plots                                 { Результирующие графики }
    grid(x+Scal*U,y+Scal*V)  as "Eigen mode"
        report Freq as "Eigen frequency"
   summary
        report Freq as "Eigen frequency"
  end