!     Расчет падения груза на балку (2D задача)
! Все данные в системе СИ
 /CONFIG,NRES,4000
/PREP7
/SHOW
/TITLE, Bouncing Block
! ВСЕ РАЗМЕРЫ В СИСТЕМЕ СИ
LBEAM=1  !  Длина балки

HB=0.8   !  Высота, на которой первоначально находился груз

L1=0.56  !  Расстояние от левого конца балки до груза по оси X
BL=0.0256 ! Ширина балки
HL=0.0125 ! Толщина (высота) балки

HA=0.025 ! Толщина груза
AB=0.06  !  Cторона квадрата, занимаемого грузом

T_DROP=SQRT(2*HB/9.8) ! Расчетное время падения груза на балку
TIME_0=0.0002  ! Время окончания первого интервала интегрирования по времени
DTIME_0=0.0001 ! Шаг по времени для первого интервала
TIME_1=T_DROP         ! Время окончания второго интервала интегрирования по времени
TIME_2=4*T_DROP       ! Время окончания третьего интервала интегрирования по времени

DTIME_1=TIME_1/10 ! Шаг по времени для второго интервала
DTIME_2=TIME_1/50! Шаг по времени для третьего интервала

ET,1,BEAM3             !  Балочный элемент (2D elastic beam), степени свободы ux,uy,rotz 
ET,2,PLANE42,,,3       !  Плоский четырехугольный 4-узловой КЭ для груза с толщиной 
ET,3,CONTA175 ! 2-D/3-D Node-to-Surface Contact
ET,4,TARGE169          !  Ответный (2-D TARGET) элемент (для балки)

! Наборы параметров (Real constants set) для типов элементов
R,1,BL*HL,(BL*HL**3)/12,HL ! Площадь поперечного сечения, момент инерции, толщина (для балки)
R,2,HA                 ! Толщина (для груза)
R,3,      !Номальная контактная жесткость - по умолчанию

! Материальные свойства типа 1 - для балки (медь)
MP,EX,1,1.2e11		! Модуль Юнга
MP,DENS,1,8.9e3		! Плотность
MP,NUXY,1,0.33		! Коэффициент Пуассона

! Материальные свойства типа 2 - для груза (сталь)
MP,EX,2,2e11		! Модуль Юнга
MP,DENS,2,7.88e3	! Плотность
MP,NUXY,2,0.29		! Коэффициент Пуассона

! Параметры конечно-элементной сетки
NE_BEAM=20     !  Число КЭ для балки
NE_BLOCK=2     !  Число КЭ на грани груза

! Твердотельная и конечно-элементная модели балки
K,1,0,0
K,2,LBEAM,0
L,1,2
! Ассоциируем с балкой материал 1, тип КЭ 1, набор real constantants 1
MAT,1 $ TYPE,1 $ REAL,1
ESIZE,,NE_BEAM ! Размер конечного элемента для балки
LMESH,ALL ! Разбиваем линию балки на элементы

! Твердотельная и конечно-элементная модели груза
RECTNG,L1,L1+AB,HB,HB+AB !Прямоугольник по двум точкам RECTNG, X1, X2, Y1, Y2
! Ассоциируем с грузом материал 2, тип КЭ 2, набор real constantants 2
MAT,2 $ TYPE,2 $ REAL,2
ESIZE,,NE_BLOCK ! Размер конечного элемента для груза
AMESH,ALL ! Разбиваем область на элементы

/ESHAPE,1 ! Показ толщины элемента
EPLOT ! Показ конечно-элементной сетки


! Создание ответных элементов на балке
MAT,1 ! Созданные элементы будут принадлежать материалу 1 (балка)
TYPE,4 ! Задание типа элемента 4  (target)
REAL,3
NSEL,S,LOC,Y,0
TSHAP,LINE ! Форма ответного элемента - линия
CM,BEAM,NODE ! Выбранные узлы объединены в группу с именем beam         
ESURF ! Генерирование ответных элементов на балке                

ASEL,ALL !Выбор всех областей (груз)
LSLA,S ! Выбор линий на областях (граница груза)
nsll,s,1 ! Выбор узлов на выбранных линиях
TYPE,3 ! Задание типа элемента 3 (contact)
CM,PUNCH,NODE   ! Выбранные узлы объединены в группу с именем punch 
ESURF ! Генерирование контактных элементов на поверхности груза       

ALLSEL,ALL ! Выбор всего
SAVE
FINISH


/SOLU
ANTYPE,TRANS     ! Нестационарная задача
LUMPM,ON         ! Диагональная матрица масс (не обязательная команда)
NLGEOM,ON        ! Опция больших перемещений

!  Условия закрепления для балки
DK,1,ALL,0	
DK,2,UY,0

! Условия закрепления для груза
NSEL,S,LOC,Y,HB,HB+AB
D,ALL,ALL,0
NSEL,ALL

ACEL,,9.8   !  Учет ускорения свободного падения

! Первый шаг (load step)
! Расчет предварительного напряженного состояния
! Получение начальных условий для нестационарного анализа
TIME,TIME_0!Время в конце первого шага
DELTIM,DTIME_0! Шаг по времени (будет два подшага)
KBC,1 !Loads are step changed (stepped) at the first substep of this load step 
!to the values of this load step (i.e., the same values are used for all substeps)
TIMINT,OFF !No transient effects
outres,all,last !  Запись в файл результата последного подшага
SOLVE ! Получение решения

! Выбор всех узлов груза
NSEL,S,LOC,Y,HB,HB+AB
DDELE,ALL,ALL ! Удаление условий закрепления
NSEL,ALL

OUTRES,ALL,ALL   !  Запись в файл результатов для всех подшагов по времени
AUTOTS,ON ! Автоматический шаг по времени
TIMINT,ON  ! Активизация нестационарных эффектов

!Второй шаг (load step)
TIME,TIME_1
DELTIM,DTIME_1,DTIME_1/5,DTIME_1*2  ! Шаг по времени, мин. и макс. подшаги по времени
SOLVE

! Третий шаг (load step)
TIME,TIME_2
DELTIM,DTIME_2,DTIME_2/10,DTIME_2  ! Шаг по времени, мин. и макс. подшаги по времени
SOLVE

FINISH