{ FlexPDE 2.14a}
 { St2LS_1.pde - РАСТЯЖЕНИЕ УПРУГОЙ ПЛАСТИНКИ С КРУГОВЫМ ОТВЕРСТИЕМ}
 { В силу симметрии задачи рассматривается четверть пластинки }

  Title 'EXTENSION OF AN ELASTIC PLATE WITH A HOLE'
  
  select
    errlim = 1e-5	{ точность при определении напряжений }
 
  variables
    U                   { U и V - переменные }
    V

  definitions
    a=5	{длина четверти пластины}
    b=2	{ширина четверти пластины}
    R=0.25	{радиус отверстия}
    p=1e3  {значение растягивающей нагрузки (кГ/см^2)}
    nu = 0.3	{ коэффициент Пуассона }
    E  = 2e6 	{ модуль Юнга  (кГ/см^2)}

    mu  = E/2/(1+nu)	{модуль сдвига}
    lambda_ =  2*mu*nu/(1-2*nu)   {коэфф. Ламе}
	{lambdaz - коэфф. Ламе для плоского напряженного состояния }
    lambdaz = 2*mu*lambda_/(lambda_+2*mu) 
    Sxx = dx(U)		{осевые деформации Sxx}
    Syy = dy(V)		{осевые деформации Syy}
    Sxy = (dy(U)+dx(V))/2	{сдвиговые деформации Sxy}
    Txx= lambdaz*(Sxx+Syy)+2*mu*Sxx        {напряжения Txx}
    Tyy= lambdaz*(Sxx+Syy)+2*mu*Syy       {напряжения Tуу}
    Txy=2*mu*Sxy			 {напряжения Txy}
    mcoeff=0.2    {масштабный коэффициент для вывода перемещений}
    Scal=mcoeff*globalmax(magnitude(x,y))/globalmax(magnitude(u,v))

    RR=sqrt(x*x+y*y)     theta=arcsin(y/RR)  {RR,  theta - полярные координаты }
    {компоненты напряжений в полярной системе координат}
    Trr=Txx*(cos(theta))^2+Tyy*(sin(theta))^2+Txy*sin(2*theta)
    Tthetatheta=Txx*(sin(theta))^2+Tyy*(cos(theta))^2-Txy*sin(2*theta)

  equations      { дифференциальные уравнения равновесия
                              для плоской задачи теории упругости}
     U:dx(Txx) +dy(Txy)  = 0
     V:dx(Txy)+dy(Tyy)  = 0
 
   
  boundaries       {описание области и граничных условий}
    region 1
      start (R,0)
      load(U)=0       {условия симметрии по оси Y=0}
      value(V)=0
      line to (a,0)   
 
      load(U)=p      {распределенная нагрузка}
      load(V) = 0
      line to (a,b)    
      
      load(U)=0        {свободная от напряжений граница }
      load(V)=0 
      line to (0,b)    

      value(U)=0     {условия симметрии по оси X=0}
      load(V) = 0
      line to (0,R) 

      load(U)=0        {свободная от напряжений граница }
      load(V)=0 
      arc(center=0,0)  to close
      

  monitors
      grid(x+Scal*U,y+Scal*V)     { показ деформированного состояния
                                       в процессе решения }

  plots                 {картинки  результов }
     grid(x+Scal*U,y+Scal*V) as "Deformed grid"     
     contour(Txx) painted as "Stress Txx"
     contour(Tyy) painted as "Stress Tyy"
     contour(Txy) painted as "Stress Txy"
     contour(Tthetatheta) painted as "Stress Tthetatheta"  
     contour(Tthetatheta)  as "Stress Tthetatheta"  
     elevation(Tthetatheta) from (0,R) to (0,b) as "Tthetatheta along the line x=0"

     contour(Trr) as "Stress Trr"
  end