!	Предметная область - теплофизика (Th)
!	Плоская задача (2)
!	Линейный анализ (L)
!	Стационарная задача (S)
!
!	Тестовая задача, иллюстрирующая решение
!	краевой задачи для уравнения теплопроводности
!	с различными типами граничных условий.
!
!	Геометрия области --- тело в форме буквы "Ь".

/TITLE, Heat Flow in Letter
/PREP7

HL=0.4 	! Толщина буквы
HF=1		! Коэффициент конвективного теплообмена
TEXT=0	! Температура окружающей среды для конвективных условий
MP,KXX,1,1	! Коэффициент теплопроводности KXX=1

! Параметры для триангуляции
DMESH=HL
DMESH1=DMESH/2

ET,1,PLANE35 ! Шестиузловой треугольный температурный КЭ PLANE35

LOCAL,11,1,0,0,,,,,2/3 ! Эллиптическая система координат 11
LOCAL,12,1,0,0,,,,,(1-HL)/(1.5-HL) ! Эллиптич. сист. коорд. 12
CSYS,0	! Переход в основную декартову систему координат
! Определение основных точек
K,1,0,-1
K,2,1.5,0
K,3,0,1
K,4,0,2.5
K,5,-HL,2.5
K,6,-HL,-1

CSYS,11
L,1,2 $ L,2,3
CSYS,0
L,3,4 $L,4,5 $ L,5,6 $ L,6,1 
AL,1,2,3,4,5,6 ! Определение площади 1 по линиям

! Определение отверстия - площади 2
K,7,0,-1+HL
K,8,1.5-HL,0
K,9,0,1-HL
CSYS,12
L,7,8 $ L,8,9
CSYS,0
L,9,7
AL,7,8,9
ASBA,1,2 ! Вырезать из области 1 область 2

! Установка размеров элементов вблизи опорных точек
KESIZE,ALL,DMESH
KESIZE,1,DMESH1 $ KESIZE,3,DMESH1 
KESIZE,7,DMESH1 $ KESIZE,9,DMESH1 
AMESH,ALL ! Триангулировать область (3)
FINISH

/SOLU
ANTYPE,STAT          ! Решение статической задачи.
NSEL,S,LOC,Y,-1	! Выбор всех узлов с координатой Y=-1
NSEL,R,LOC,X,-HL,0
D,ALL,TEMP,10	! Задать для всех выбранных узлов TEMP=10
NSEL,S,LOC,Y,2.5	! Выбор всех узлов с координатой Y=2.5
SF,ALL,CONV,HF,TEXT ! Конвентивный теплообмен в выбранных узлах
NSEL,ALL		! Вернуться к выбору всех узлов модели

SOLVE			! Решить СЛАУ МКЭ
FINISH

/POST1
PLNSOL,TEMP		! Показать поле температуры