!  Th2LS_1.INP  - program for ANSYS
!	Thermal analysis (Th)
!	Plane problem (2)
!	Linear Analysis (L)
!	static problem (S)
!
!	Thermal conductivity problem with different boundary conditions 

!
!	Geometry of the domain - body in the shape of letter "R".

/TITLE, Heat Flow in 2D region (R)
/PREP7

!  Input data in SI system

! Geometrical sizes of the letter "R"
HL=1.4 	 ! height 
WL=0.8   ! width 
WWL=0.2 ! width of the walls of "R"
HAL=0.7 ! additional parameter

T_INP1=90   ! Temperature at the left lower boundary
T_INP2=180   ! Temperature at the right lower boundary
T_EXT=0	! External temperature T_EXT=0
H_F=60	! Convective heat transfer coefficient

MP,KXX,1,46.7 ! Thermal conductivity coefficient KXX=46.7 (Steel)

! Parameters for finite element mesh
DMESH=WWL/2
DMESH1=DMESH/4

ET,1,PLANE35 ! 6-node triangular thermal finite element PLANE35

PEL=(HAL/2)/(WL-WWL) ! Ellipticity parameter for the curved part of the figure
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Elliptical coordinate system 11
CSYS,0	! Change active coordinate system to Cartesian 

! Define main keypoints for external boundary
K,1,0,0
K,2,WWL,0
K,3,WWL,HL-HAL-WWL
K,4,WL-WWL,0
K,5,WL,0
K,6,WWL,HL-HAL
K,7,WL,HL-HAL/2
K,8,WWL,HL
K,9,0,HL

 !   Define lines by end keypoints
L,1,2 $ L,2,3  $ L,3,4 $ L,4,5 $ L,5,6
CSYS,11    ! Change active coordinate system to coordinate system 11
L,6,7 $ L,7,8
CSYS,0 !  Change active coordinate system to Cartesian 
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 ! Define area 1 by lines

!Define the hole - area 2
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL
K,11,WL-WWL,HL-HAL/2
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL
CSYS,11
L,10,11 $ L,11,12
CSYS,0
L,12,10
AL,10,11,12
ASBA,1,2 ! Substract area 2 from area 1

! Define element sizes in the vicinity of the keypoints
KESIZE,ALL,DMESH
KESIZE,3,DMESH1 $ KESIZE,6,DMESH1 
KESIZE,10,DMESH1 $ KESIZE,11,DMESH1 $ KESIZE,12,DMESH1 
AMESH,ALL ! Mesh all areas (area 3)
FINISH

/SOLU
ANTYPE,STAT          ! Static analysis
NSEL,S,LOC,Y,0	! Select all nodes with coordinate Y=0
NSEL,R,LOC,X,0,WWL ! From selected set reselect all nodes with coordinate 0<=x<=wwl
D,ALL,TEMP,T_INP1	! Define input temperature value for all selected nodes TEMP=T_INP1
NSEL,S,LOC,Y,0	! Select all nodes with coordinate Y=0
NSEL,R,LOC,X,WL,WL-WWL ! From selected set reselect all nodes with coordinate wwl<=x<=wl-wwl
D,ALL,TEMP,T_INP2	! Define input temperature value for all selected nodes TEMP=T_INP2
NSEL,S,LOC,Y,HL	! Select all nodes with coordinate Y=HL
NSEL,R,LOC,X,0,WWL ! From selected set reselect all nodes with coordinate 0<=x<=wwl
SF,ALL,CONV,H_F,T_EXT ! For all selected nodes define convective heat transfer
NSEL,ALL		! Select all nodes of the model

SOLVE			! Solve FE system of equations
SAVE,Heat_Letter_R,db   ! Save the current databas under the name Heat_Letter_R.db
FINISH

/POST1
!  Commands for graphical output
/SHOW,WIN32C
/TRIAD,OFF         ! Don't show the triad (origin of coordinates)
/PLOPTS,INFO,2     ! Auto-legend format for caption
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   ! ANSYS logo in text format 
/PLOPTS,FRAME,OFF  ! Don't show frame
/PLOPTS,TITLE,OFF  ! Don't show title
/PLOPTS,MINM,ON
/PLOPTS,DATE,OFF   ! Don't show date
/CONT,,14 ! Specifies the number of uniform contour values
! Convert background from black to white
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15 

/PBC,TEMP,,1	!   display boundary conditions for temperature
/PSF,CONV,HCOEF,2 !  Display boundary conditions for thermal heat transfer with arrows 
PLNSOL,TEMP		!   Plot temperature distribution