/TITLE, Plane Stress tension of an elastic plate with a hole
/PREP7
! Due to the symmetry of the problem we consider a quarter of the plate
A=5 ! length of the plate quarter
B=2 ! width of the plate quarter
R=0.25 ! radius of the hole
H=0.1 ! thickness of the plate
P=1e3 ! magnitude of tensile load(kG/cm^2)
!1kG = 9.8 N/m^2
MP,EX,1,2e6 ! Young's moduus EX=2*10+6 (kG/cm^2)
MP,NUXY,1,0.3 ! Poisson's ratio NUXY=0.3
ET,1,PLANE183 ! Eight-node finite element PLANE183 (plane stress)
! In Ansys11 choose PLANE82
! ******************************************************
! For stress analysis of the plate we can also choose shell element SHELL63, in this case uncomment the following commands
!ET,1,SHELL63
!R,1,H
!P=P*H ! pressure for a length unit (kG/cm)
! ******************************************************
K,1,0,0 ! Keypoints of the plate boundary: point number and coordinates
K,2,A,0
K,3,A,B
K,4,0,B
A,1,2,3,4 ! Define area 1 using four keypoints
! Command A defines an area by connecting keypoints (max 18 points). Keypoints must be input in a clockwise or counterclockwise order around the area.
APLOT,1 ! Show area 1
PCIRC,R ! Define area 2 - a cirlce with radius R and center in (0,0)
ASBA,1,2 ! Substract area 2 from area 1
APLOT,ALL ! Show resulting area 3
! Define parameters for finite element mesh
! KESIZE Specifies the edge lengths of the elements nearest a keypoint
KESIZE,ALL,B/4
KESIZE,5,R/6 ! set element edge length near keypoint 5
KESIZE,6,R/6 ! set element edge length near keypoint 6
AMESH,ALL ! mesh area all areas (area 3)
FINISH
/SOLU
ANTYPE,STAT ! set analysis type: static
NSEL,S,LOC,X,A ! select all nodes with coordinate X=A
SF,ALL,PRES,-P ! for all selected nodes set surface load PRES = -P
NSEL,ALL ! select all nodes
DL,9,,SYMM ! symmetry condition on line 9 (all lines with Y=0)
DL,10,,SYMM ! symmetry condition on line 10 (all lines with X=0)
! ********************************************************
! For finite element with degrees of freedom UX, UY the previous symmetry conditions on lines 9 and 10 are equivalent to the following commands
!NSEL,S,LOC,X,0 !Select all nodes with coordinate x=0
!D,ALL,UX,0 ! for all selected nodes set displacement ux=0
!NSEL,S,LOC,Y,0 !Select all nodes with coordinate y=0
!D,ALL,UY,0 ! for all selected nodes set displacement uy=0
!NSEL,ALL ! select all nodes
! ********************************************************
SOLVE ! Solve finite element system of equations
FINISH