! File   FE_Mod_CP_2.inp
! Test problem No. 2 
! TWO-DIMENSIONAL PROBLEM 
! THERMOELASTIC BODY 
! Transient problem 

! Invert background from black to white  
/RGB,INDEX,100,100,100,0 
/RGB,INDEX,0,0,0,15 

/PREP7 
!  All values in SI system 

TES1=10   ! time value at the end of the first step 
TES2=120 ! time value at the end of the second step 
!  substeps for time steps 
DT1=1   ! substep value for the step 1 
DT2=2   ! substep value for the step 2 

! Conditions for thermal analysis 
T_INP1=0   ! Temperature on the bottom edge 
T_INP2=90  ! Temperature on the right top edge (for time step 1)

T_EXT=0 ! Ambient temperature for convective heat transfer conditions 
H_F=60  ! Coefficient of convective heat transfer 

! Temperature difference from zero to absolute zero 
TOFFST, 273 
! For TOFFST=0 a heat equation is a thermal conductivity equation
! TOFFST, 0

!  Material properties (steel) 
E1=2.1e11 ! Young's modulus 
NU1=0.29 ! Poisson's ratio 
RHO1=7.8e3 ! Density 
K1=46.7 ! Thermal conductivity coefficient 
C1=462 ! Specific heat 
ALPH1=1.51e-05 ! Coefficient of thermal expansion 

MP,EX,1,E1 
MP,DENS,1,RHO1 
MP,NUXY,1,NU1 
MP,KXX,1,K1 
MP,C,1,C1 
MP,ALPX,1,ALPH1 

! Commands to analyze the capabilities for not taking into account 
! dynamic terms in the motion equations

! KAPPA=1e-6 
! MP,DENS,1,RHO1*KAPPA 
! MP,C,1,C1/KAPPA 

ET,1,PLANE223,11,,2  ! Quadrilateral finite element with 8 nodes
                     ! Degrees of freedom UX, UY, TEMP, plane strain  

! Geometrical sizes of the body in the shape of letter ``R'' 
HL=0.14    ! Height 
WL=0.08    ! Width 
WWL=0.02 ! Width of the walls of letter ``R'' 
HAL=0.07 ! Additional size along the height 

! Meshing parameters
DMESH=WWL/4 

PEL=(HAL/2)/(WL-WWL) ! Ellipticity parameter for curvilinear part 
LOCAL,11,1,WWL,HL-HAL/2,,,,,PEL ! Elliptical CS with number 11 
CSYS,0  ! Change active coordinate system to Cartesian 

! Build the geometry of the domain 
! External part - area 1 
K,1,0,0 
K,2,WWL,0 
K,3,WWL,HL-HAL-WWL 
K,4,WL-WWL,0 
K,5,WL,0 
K,6,WWL,HL-HAL 
K,7,WL,HL-HAL/2 
K,8,WWL,HL 
K,9,0,HL 
L,1,2 $ L,2,3 $ L,3,4 $ L,4,5 $ L,5,6 

CSYS,11 
L,6,7 $ L,7,8 
CSYS,0 
L,8,9 $ L,9,1 
AL,1,2,3,4,5,6,7,8,9 

! Hole - area 2 
K,10,WWL,HL-HAL/2-(WL-2*WWL)*PEL 
K,11,WL-WWL,HL-HAL/2 
K,12,WWL,HL-HAL/2+(WL-2*WWL)*PEL 
CSYS,11 
L,10,11 $ L,11,12 
CSYS,0 
L,12,10 
AL,10,11,12 
ASBA,1,2 ! Subtract area 2 from area 1

! Set the size of finite elements 
ESIZE,DMESH 

AMESH,ALL 

!  Conditions for rigidly fixed boundary 
NSEL,S,LOC,Y,0    ! Select the nodes on the bottom (along Y-axis) 
D,ALL,UX,0 
D,ALL,UY,0 
NSEL,ALL ! Select all nodes of the model 

!  Select the nodes to monitor the results 
!  Node N1_MON is in the upper part of the domain 
!  Y=HL, X=WWL 
NSEL,S,LOC,Y,HL,HL 
NSEL,R,LOC,X,WWL 
*GET,N1_MON,NODE,,NUM,MIN 
!  Node N2_MON is below at X=WWL

NSEL,S,LOC,Y,HL-HAL/2-(WL-2*WWL)*PEL 
NSEL,R,LOC,X,WWL 
*GET,N2_MON,NODE,,NUM,MIN 
NSEL,ALL 

FINISH

! Solution of coupled thermoelastic problem 
/SOLU ! Enter the solver 
ANTYPE,TRANS !  Select the analysis type: transient analysis
KBC,0   ! Specify linearly interpolated (ramped) load 

!  Damping coefficient in time integration scheme 
!TINTP,0.005  ! TINTP=0.005 - default value 
TIME,TES1     ! Time at the end of step 1 
DELTIM,DT1  ! Substep for step 1 

NSEL,S,LOC,Y,0    ! Select the nodes on the bottom (by Y-axis) 
D,ALL,TEMP,T_INP1 ! For all selected nodes set TEMP=T_INP1 

NSEL,S,LOC,Y,HL,HL   ! Select the nodes on the top (by Y-axis)
NSEL,R,LOC,X,0,WWL 
D,ALL,TEMP,T_INP2   ! For all selected nodes set TEMP=T_INP2

NSEL,ALL 
! Write to the database the results of nodal solution 
! for all substeps
OUTRES,BASIC,ALL 
SOLVE 

! Step 2 
TIME,TES2 
DELTIM,DT2 
KBC,1  ! Constant values of external influences

NSEL,S,LOC,Y,HL,HL   ! Select the nodes on the top (by Y-axis) 
NSEL,R,LOC,X,0,WWL  
DDEL,ALL,TEMP ! Remove the conditions TEMP=T_INP2

SF,ALL,CONV,H_F,T_EXT ! Convective heat transfer in the selected nodes

NSEL,ALL 

SOLVE 
SAVE 
FINISH 

/POST26 
/SHOW,WIN32C ! Specify device for graphical output
/TRIAD,OFF         ! Do not show the global coordinate triad

/PLOPTS,INFO,2     ! Use Auto-legend format 
/PLOPTS,LEG2,OFF 
/PLOPTS,LOGO,OFF   ! Do not show ANSYS logo
/PLOPTS,FRAME,OFF ! Do not show frame 
/PLOPTS,DATE,OFF   ! Do not show date 
/COLOR,CURVE,WHIT,1,6 ! Curve color for graphs -- white 
                      ! (black after inversion) 
/COLOR,GRID,WHIT ! Grid color -- white (black after inversion)
/GMARKER,1,2,3 ! Label 2 for curve 1 -- boxes, for every 3rd value 
/GMARKER,2,4,3 ! Label 4 for curve 2 -- crosses, for every 3rd value 
/GRID,1 ! Grid by X and Y (full grid) 

/XRANG,0,TES2 
/AXLAB,Y,Temperature (degree)  ! Label for Y-axis 
/AXLAB,X,Time (sec) ! Label for X-axis 
NSOL,2,N1_MON,TEMP,,TEMP1  ! Variable 2 -- temperature in node N1_MON 
NSOL,3,N2_MON,TEMP,,TEMP2 

NSOL,4,N1_MON,U,Y,UY1  ! Variable 4 -- displacement UY in node N1_MON 
NSOL,5,N2_MON,U,Y,UY2 

PLVAR,2,3  ! Plot graphs of variables 2, 3 versus time (variable 1) 

! Remove comments to show UY in control nodes 
! /AXLAB,Y,UY (m) 
! PLVAR,4,5