! File    FE_Mod_CP_3_sm.inp
! Test problem No.~3
! PLANE PROBLEM
! OSCILLATIONS OF A COMPOUND RING (CYLINDER)
!
! Calculation of natural frequencies of the body without fluid

! Invert background from black to white
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15

/PREP7
F_R='FE_Mod_CP_3_sm' ! file name for results

! Parameters for geometrical sizes (all in SI system)

R1=0.25 ! inner radius of the ring
R2=0.26 ! middle radius of the ring
R3=0.27 ! outer radius of the ring

NFREQ=4   !  number of output frequencies
FBEG=0.1  !  start value for the frequency range
FEND=1e10 ! end value for the frequency range

! Material properties of the body
! Material constants of steel
RO1=7.86e3 ! density
E1=2e11 ! Young's modulus
NU1=0.29 ! Poisson's ratio
! Material constants of copper
RO2=8.9e3
E2=1.2e11
NU2=0.33

MP,DENS,1,RO1       !  density of the medium 1
MP,EX,1,E1          ! Young's modulus of the medium 1
MP,NUXY,1,NU1       ! Poisson's ratio of the medium 1
MP,DENS,2,RO2       !  density of the medium 2
MP,EX,2,E2          ! Young's modulus of the medium 2
MP,NUXY,2,NU2       ! Poisson's ratio of the medium 2

ET,1,PLANE42,,,2  ! Elastic finite element with 4 nodes, plane strain

! Parameters of finite element mesh
SM=1.00  ! Scaling multiplier
HDIV=2*SM ! Number of elements along the thickness (for one material)

TDIV=32*SM ! Number of elements along the circumferential direction

/OUTPUT,F_R,res
*VWRITE
(1X,'   MODAL ANALYSIS (Block Lanczos, Plane42)')
*VWRITE,NFREQ
(1X,'   NFREQ= ',F4.0)
*VWRITE,HDIV,TDIV
(1X,'   HDIV= ',F4.0,'   TDIV= ',F4.0)
/OUTPUT
*DIM,FR,ARRAY,NFREQ  ! Array for natural frequencies

! Geometry of the model
CSYS,1 ! Change active coordinate system to cylindrical
K,1,R1 $ K,2,R2 $ K,3,R3
K,4,R3,90 $ K,5,R2,90 $ K,6,R1,90
L,6,1 $ L,1,2 $ L,2,5 $ L,5,6 $ L,2,3 $ L,3,4 $ L,4,5
A,1,2,5,6
A,2,3,4,5
CSYS,0 ! Change active coordinate system to Cartesian

! Divide lines
LESIZE,1,,,TDIV $ LESIZE,3,,,TDIV $ LESIZE,6,,,TDIV

LESIZE,2,,,HDIV $ LESIZE,5,,,HDIV
LESIZE,4,,,HDIV $ LESIZE,7,,,HDIV
MSHKEY,1
MSHAPE,0,2D
ASEL,S,AREA,,2 ! Select new set of areas - area 2
AATT,2,,1 ! Associate material 2 and element type 1 (MAT=2,  TYPE=1)
          ! with selected area
ASEL,ALL  ! Select all areas
AMESH,ALL ! Mesh all areas
FINISH

/SOLU
ANTYPE,MODA  ! Modal analysis
! Block Lanczos method
! Number of frequencies NFREQ in the interval FBEG,FEND
MODOPT,LANB,NFREQ,FBEG,FEND

! Conditions of symmetry
LSEL,S,LOC,Y,0
LSEL,A,LOC,X,0
DL,ALL,,SYMM
LSEL,ALL

SOLVE
FINISH

/POST1
! Output the table of resonance frequencies into the file
*DO,I,1,NFREQ
   SET,,I
   *GET,FR(I),MODE,I,FREQ
   FRI=FR(I)
   /OUTPUT,F_R,res,,append
   *VWRITE,I,FRI
   (1X,F4.0,'   ',E12.5)
   /OUTPUT
*ENDDO

! Plot pictures of mode shapes
/PNUM,MAT,1 ! Enumerate elements by material properties

/NUMBER,1   ! Show numbers only by color
/TRIAD,OFF !  Do not show the global coordinate triad
/PLOPTS,LOGO,OFF ! Do not show ANSYS logo
/PLOPTS,DATE,OFF ! Do not show date
/PLOPTS,FRAME,OFF ! Do not show frame
/WINDOW,1,LTOP    ! Place Window 1 at the left top of the screen
SET,,1 ! read data for the first mode
PLDISP,2 ! show mode shape together with undeformed shape

/WINDOW,1,OFF ! Make Window 1 passive
/NOERASE ! Don not erase window content
/WINDOW,2,RTOP ! Place Window 2 at the right top of the screen
SET,,2  ! read data for the second mode
PLDISP,2
/WINDOW,2,OFF
/WINDOW,3,LBOT ! Place Window 3 at the left bottom of the screen
SET,,3 ! read data for the third mode
PLDISP,2
/WINDOW,3,OFF
/WINDOW,4,RBOT ! Place Window 4 at the right bottom of the screen
SET,,4 ! read data for the fourth mode
PLDISP,2

! Return to default settings (one window at full screen)
/WINDOW,1,ON
/WINDOW,1,FULL
/WINDOW,4,OFF

! Execute this command to erase the content of the window
! ERASE