! File    FE_Mod_CP_3_ha.inp
! Test problem No. 3
! PLANE PROBLEM
! OSCILLATIONS OF A COMPOUND RING (CYLINDER) IN ACOUSTIC MEDIUM
!
! Calculation of natural frequencies of the body with fluid
! Infinite elements FLUID129

! Invert background from black to white
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15

/PREP7
F_R='FE_Mod_CP_3_ha_4_SM1' ! file name for output results

! Parameters for geometrical sizes (all in SI system)

R1=0.25 ! inner radius of the ring
R2=0.26  ! middle radius of the ring
R3=0.27  ! outer radius of the ring
KRA=4     ! coefficient for the computation of the radius RA
RA=KRA*R3 ! radius for external boundary of the fluid

FP=100 ! Force value
NFREQ=100   !  number of output frequencies
FBEG=100  !  start value for the frequency range
FEND=150 ! end value for the frequency range

! Material properties
!  Material constants of steel
RO1=7.86e3 ! density
E1=2e11 ! Young's modulus
NU1=0.29    ! Poisson's ratio
! Material constants of copper
RO2=8.9e3
E2=1.2e11
NU2=0.33
! Material constants of fluid
ROA=1030
CA=1560
AD=1

MP,DENS,1,RO1   !  density of medium 1
MP,EX,1,E1      ! Young's modulus of medium 1
MP,NUXY,1,NU1   ! Poisson's ratio of medium 1

MP,DENS,2,RO2   !  density of medium 2
MP,EX,2,E2      ! Young's modulus of medium 2
MP,NUXY,2,NU2   ! Poisson's ratio of medium 2

MP,DENS,3,ROA   !  density of acoustic medium
MP,SONC,3,CA ! speed of sound in acoustic medium
MP,MU,3,AD ! absorbing coefficient at the impedance boundary

ET,1,PLANE42,,,2  ! Elastic finite element with 4 nodes, plane strain
ET,2,FLUID29,,1   ! Acoustic finite element with 4 nodes,  without UX & UY
ET,3,FLUID29      ! Acoustic finite element with 4 nodes,  with UX & UY
ET,4,FLUID129     ! Acoustic finite element for infinite boundaries
R,4,RA ! Radius of infinite boundary for finite element FLUID129

! Parameters of finite element mesh
SM=1.00  ! scaling multiplier
HDIV=2*SM  ! Number of FEs along the thickness (for one material)

TDIV=32*SM ! Number of FEs along the circumferential direction
HADIV=32*SM ! Number of FEs along the radial direction for acoustic medium
SPACE=3 ! Multiplier to increase the length of acoustic FE
        ! along the radial direction

/OUTPUT,F_R,res
*VWRITE
(1X,'   HARMONIC  ANALYSIS (Plane42, Fluid29)')
*VWRITE,KRA
(1X,'   RA/R3= ',F4.0)
*VWRITE,NFREQ
(1X,'   NFREQ= ',F4.0)
*VWRITE,HDIV,TDIV,HADIV
(1X,'   HDIV= ',F4.0,'   TDIV= ',F4.0,'   HADIV= ',F4.0)
/OUTPUT

! Geometry of the model
CSYS,1 ! Change active coordinate system to cylindrical
K,1,R1 $ K,2,R2 $ K,3,R3
K,4,R3,90 $ K,5,R2,90 $ K,6,R1,90
L,6,1 $ L,1,2 $ L,2,5 $ L,5,6 $ L,2,3 $ L,3,4 $ L,4,5
A,1,2,5,6 $ A,2,3,4,5
K,7,RA $ K,8,RA,90
L,3,7 $ L,7,8 $ L,8,4
A,3,7,8,4
CSYS,0 ! Change active coordinate system to Cartesian

! Line division
LESIZE,1,,,TDIV $ LESIZE,3,,,TDIV $ LESIZE,6,,,TDIV
LESIZE,2,,,HDIV $ LESIZE,5,,,HDIV
LESIZE,4,,,HDIV $ LESIZE,7,,,HDIV
LESIZE,9,,,TDIV
LESIZE,8,,,HADIV,SPACE
LESIZE,10,,,HADIV,1/SPACE
MSHKEY,1
MSHAPE,0,2D
ASEL,S,AREA,,2 ! Select new set of areas - area 2
AATT,2,,1  ! Associate material 2 and element type 1 (MAT=2,  TYPE=1)
           ! with the selected area
ASEL,S,AREA,,3 ! Select new set of areas - area 3
AATT,3,,2 ! Associate material 3 and element type 2 (MAT=3,  TYPE=2)
          ! with the selected area
ASEL,ALL  ! Select all areas
AMESH,ALL ! Mesh all areas

! Change acoustic finite elements on the border of the ring to type 3

LSEL,S,LINE,,6 ! Select line 6 - border of the ring and acoustic medium
NSLL,S,1 ! Select nodes on the selected lines
ESLN,S,0 ! Select finite elements that are attached to the selected nodes
ESEL,U,TYPE,,1 ! Unselect elements of type 1 from the selected set

EMODIF,ALL,TYPE,3  ! Modify all selected elements to type 3
ALLSEL

! Fluid-Structure Interface (FSI)
CSYS,1
NSEL,S,LOC,X,R3 ! Select the nodes at the border of solid and fluid bodies

ESLN ! Select elements attached to the selected nodes
ESEL,R,TYPE,,3 ! Select finite elements that have TYPE=3
SF,ALL,FSI ! Set the flag FSI for the contact nodes
NSEL,ALL
ESEL,ALL
CSYS,0

FINISH

/SOLU
ANTYPE,HARMIC   ! Steady-state oscillations
HROPT,FULL
HARFRQ,FBEG,FEND
NSUBST,NFREQ
KBC,1

! Symmetry conditions
LSEL,S,LOC,Y,0
LSEL,A,LOC,X,0
DL,ALL,,SYMM
LSEL,ALL

CSYS,1
KSEL,S,LOC,X,R1
KSEL,R,LOC,Y,0
FK,ALL,FX,-FP/2  ! Divide FP into 2, as we consider half of the model

KSEL,ALL
CSYS,0

! Define infinite elements FLUID129
CSYS,1
NSEL,S,LOC,X,RA ! Select nodes at the impedance boundary
TYPE,4 $ REAL,4 $ MAT,3
ESURF
ESEL,ALL
NSEL,ALL
CSYS,0

OUTRES,BASIC,ALL
SOLVE
SAVE
FINISH

/POST26
/SHOW,WIN32C
/TRIAD,OFF         ! Do not show the global coordinate triad

/PLOPTS,INFO,2     ! Use auto-legend
/PLOPTS,LEG2,OFF
/PLOPTS,LOGO,OFF   !  Do not show ANSYS logo
/PLOPTS,DATE,OFF    ! Do not show date
/PLOPTS,FRAME,OFF  ! Do not show frame

/COLOR,CURVE,WHIT,1,6
/COLOR,GRID,WHIT
/GRID,1

CSYS,1
NSEL,S,LOC,X,R3
NSEL,R,LOC,Y,90 ! Node with number N_RES1 is the point (0,R3) in Cartesian CS
*GET,N_RES1,NODE,,NUM,MIN
NSEL,S,LOC,X,RA
NSEL,R,LOC,Y,90 ! Node with number N_RES2 is the point (0,RA) in Cartesian CS
*GET,N_RES2,NODE,,NUM,MIN
NSEL,ALL
CSYS,0

/XRANG,FBEG,FEND
/AXLAB,X,Frequency (Hz)
/AXLAB,Y,Displacement UY (m)
NSOL,2,N_RES1,UY
ABS,3,2,,ABSUY
*GET,FRES,VARI,3,EXTREM,TMAX ! Define resonance frequency

/OUTPUT,F_R,res,,append
*VWRITE,FRES
(1X,'   FRES= ',E12.5)
PRVAR,2
/OUTPUT PLCPLX,2 ! Real part
PLVAR,2

! PLVAR,3 ! Amplitude  UY

! Commands to plot the pressure at the same point
! NSOL,4,N_RES1,PRES
! /AXLAB,Y,Acoustic pressure PRES (Pa)
! PLVAR,4