!   St3SCONT.INP  - input file for ANSYS
!	Analysis type - structural (St)
!	3D problem (3)
!	Static problem(S)
!       Contact problem (CONT)
!
!	3D Contact interaction of a roller pair
!
/TITLE, Contact interaction of a roller pair
/PREP7
! Geometrical sizes for the upper and lower rollers
R1=0.02     ! Radius of the upper roller
R2=0.02     ! Radius of the lower roller
R3=0.012   ! Radius of the notch curvature for the upper roller
R4=0.015   ! Radius of the notch curvature for the lower roller
h1=0.004    ! Half width of the upper roller
h2=0.005    ! Half width of the lower roller
h3=0.0005  ! Notch depth of the lower roller

! Material constants for the upper and lower rollers
E1=2.5e11    ! Young’s modulus of the upper roller
E2=2e11       ! Young’s modulus of the lower roller
NU1=0.29    ! Poisson’s ratio of the upper roller
NU2=0.29    ! Poisson’s ratio of the lower roller

! Geometrical sizes of the initial areas for the upper and lower rollers
d1=0.003    ! width of the contact zone on the upper roller
d2=0.003   ! width of the contact zone on the lower roller
PSIX_BOTTOM=12 ! Opening angle along X-axis for the lower initial area
PSIX_TOP=15 ! Opening angle along X-axis for the upper initial area
PSIZ_BOTTOM=21 ! Opening angle along Z-axis for the lower initial area
PSIZ_TOP=18! Opening angle along Z-axis for the upper initial area

! Meshing parameters
GLSIZE=0.0029 ! Characteristic element size
SIZE_ALL=GLSIZE/5 ! Element size for the auxiliary volumes around the contact zone
SIZE_0=GLSIZE/20 ! Element size around the contact point

!Force value
PY=0.225e3

! Define material properties
MP,EX,1,E1      ! Young’s modulus of the upper roller
MP,NUXY,1,NU1   ! Poisson’s ratio of the upper roller
MP,EX,2,E2      ! Young’s modulus of the lower roller
MP,NUXY,2,NU2   ! Poisson’s ratio of the lower roller

! Element types
ET,1,SOLID92 ! 3-D quadratic 10-node element 
ET,2,TARGE170    ! 3-D contact element
ET,3,CONTA174   ! 3-D target element


! Solid model
! Define keypoints
K,1,0,0
K,2,sqrt(h3*(2*R4-h3)),h3
K,3,h2,h3
K,4,h2,-(R2-h3) 
K,5,0,-(R2-h3)
K,6,0,R3
K,7,0,R4
K,8,0,R1
K,9,h1,R1
K,10,h1,R3-sqrt(R3*R3-h1*h1)
K,11,0,0
K,12,0,0
K,13,0,R4
CLOCAL,11,1,0,R4,0 ! Define cylindrical coordinate system 11
CSYS,11 ! Change actual CS to a user-defined CS 11
K,14,R4,-90+PSIX_BOTTOM
K,15,R4+d2,-90+PSIX_BOTTOM 
K,16,R4+d2,-90
CSYS,0   ! Change actual CS to Global Cartesian
K,17,0,R3
CLOCAL,22,1,0,R3,0  ! Define cylindrical coordinate system 22
CSYS,22 ! Change actual CS to a user-defined CS 22
K,18,R3,-90
K,19,R3,-90+PSIX_TOP
K,20,R3-d1,-90+PSIX_TOP
K,21,R3-d1,-90
CSYS,0  ! Change actual CS to Global Cartesian

! Define arcs 1-6
LARC,1,2,7,R4
LARC,11,10,6,R3
LARC,12,14,13,R4
LARC,16,15,13,R4+d2
LARC,18,19,17,R3
LARC,21,20,17,R3-d1

! Define straight lines 7-17
L,12,16
L,14,15
L,21,18
L,20,19
L,2,3
L,3,4
L,4,5
L,5,1
L,11,8
L,8,9
L,9,10

! Define areas 1-4 by keypoints
A,11,8,9,10
A,1,2,3,4,5
A,21,20,19,18
A,12,14,15,16

! Create a volume by rotating area 3 around the axis with keypoints 8 and 9 at the angle PSIZ_BOTTOM
VROTAT,3,,,,,,8,9,PSIZ_BOTTOM
! Create a volume by rotating area 4 around the axis with keypoints 4 and 5 at the angle PSIZ_TOP
VROTAT,4,,,,,,4,5,PSIZ_TOP
! Create a volume by rotating area 1 around the axis with keypoints 8 and 9 at the angle of 180 degrees
VROTAT,1,,,,,,8,9,180
! Create a volume by rotating area 2 around the axis with keypoints 4 and 5 at the angle of 180 degrees
VROTAT,2,,,,,,4,5,180

! Overlap volumes (generate new volumes in place of intersecting volumes)
VOVLAP,ALL

! Associate sets of material properties with volumes
VSEL,S,VOLU,,1  ! Select volume 1
VSEL,A,VOLU,,4   ! Add volume 4 to the set
VSEL,A,VOLU,,8   ! Add volume 8 to the set
VATT,1,,1 ! Associate material and element type attributes MAT=1, TYPE=1 with selected volumes
VSEL,S,VOLU,,9  ! Select volume 9
VSEL,A,VOLU,,6,7! Add volumes 6 and 7 to the set
VATT,2,,1! Associate material and element type attributes MAT=2, TYPE=1 with selected volumes
VSEL,ALL   ! Select all volumes

! Set the first element size around all keypoints
KESIZE,ALL,SIZE_ALL
! Set the second element size in the vicinity of the contact point
KESIZE,18,SIZE_0
! Mesh volumes 1 and 7
VMESH,1
VMESH,7
! Set the third element size around all keypoints
KESIZE,ALL,GLSIZE
! Mesh volumes 4,6,8 and 9
VMESH,4
VMESH,6
VMESH,8
VMESH,9

! Define contact elements
ASEL,S,AREA,,34 ! Select area 34
ASEL,A,AREA,,40  ! Add area 40
NSLA,,1  ! Select nodes associated with selected areas
CM,STRIP,NODE  ! Combine selected nodes into a group STRIP
TYPE,3  ! Set element type 3 (contact)
MAT,2  ! Set material type 2
ESURF  ! Generate contact elements for the selected nodes
ASEL,S,AREA,,7  ! Select area 7
ASEL,A,AREA,,38  ! Add area 38
NSLA,,1 ! Select nodes associated with selected areas
TSHAP,CIRC ! Set circular shape for target elements
CM,PUNCH,NODE ! Combine selected nodes into a group PUNCH
TYPE,2  ! Set element type 2 (target)
MAT,1  ! Set material type 1
ESURF  ! Generate contact elements for the selected nodes
NSEL,ALL  ! Select all nodes
ASEL,ALL  ! Select all areas

SAVE
FINISH

/SOLU
! Lower roller is rigidly fixed
LSEL,S,LINE,,13  ! Select line 13
NSLL,,1  ! Select nodes associated with selected lines
D,ALL,UX,0  ! Define UX=0 at all selected nodes
D,ALL,UY,0! Define UY=0 at all selected nodes
D,ALL,UZ,0! Define UZ=0 at all selected nodes
NSEL,ALL  ! Select all nodes
LSEL,ALL   ! Select all lines

! Define symmetry boundary conditions
DA,3,SYMM ! Generate symmetry constraints on area 3
DA,8,SYMM ! Generate symmetry constraints on area 8
DA,19,SYMM ! Generate symmetry constraints on area 19
DA,22,SYMM ! Generate symmetry constraints on area 22
DA,31,SYMM ! Generate symmetry constraints on area 31
DA,32,SYMM ! Generate symmetry constraints on area 32
DA,33,SYMM ! Generate symmetry constraints on area 33
DA,35,SYMM ! Generate symmetry constraints on area 35
DA,36,SYMM ! Generate symmetry constraints on area 36
DA,37,SYMM ! Generate symmetry constraints on area 37
DA,39,SYMM ! Generate symmetry constraints on area 39
DA,41,SYMM ! Generate symmetry constraints on area 41

! Define force load
FK,8,FY,-PY/4 ! Define concentrated force at keypoint 8

SOLVE      ! Solve system of finite element equations
SAVE

FINISH

/POST1
/DSCALE,ALL,OFF ! Turn off displacements scaling
/PLOPTS,INFO,1  ! Display legend on the right
PLNSOL,U,Y  ! Plot displacements UY
! Use delay to view the previous picture
*ASK,TMP,ANY NUMBER OR PRESS "ENTER"
PLNSOL,S,Y ! Plot axial stresses SY

ESEL,S,MAT,,2 ! Select elements with attribute MAT=2
NSLE,,1 ! Select nodes associated with selected elements
! Select node located at the point with coordinates (0,0,0)
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,0
! Set parameter N_CONT2 for the node with minimal number in this location
*GET,N_CONT2,NODE,,NUM,MIN
NSEL,ALL ! Select all nodes
ESEL,ALL ! Select all elements
DELTA2=UY(N_CONT2)! Define displacement UY at node N_CONT2 as DELTA2

ESEL,S,MAT,,1 ! Select elements with attribute MAT=1
NSLE,,1 ! Select nodes associated with selected elements
! Select node located at the point with coordinates (0,0,0)
NSEL,S,LOC,X,0
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,0
! Set parameter N_CONT1 for the node with minimal number in this location
*GET,N_CONT1,NODE,,NUM,MIN
NSEL,ALL ! Select all nodes
ESEL,ALL ! Select all elements
DELTA1=UY(N_CONT1)! Define displacement UY at node N_CONT1 as DELTA1

! Define stress SY at node N_CONT1 as SYY_CONT1
*GET,SYY_CONT1,NODE,N_CONT1,S,Y
! Define stress SY at node N_CONT2 as SYY_CONT2
*GET,SYY_CONT2,NODE,N_CONT2,S,Y