!     Block dropping on a beam (2D problem)
! All input data in SI system
/PREP7
/SHOW
/TITLE, Bouncing Block
LBEAM=1  !  Length of the beam
HB=0.8   !  Height of the block location
L1=0.56  !  Distance from the left end of the beam to the block along X-axis
BL=0.0256 ! Width of the beam
HL=0.0125 ! Thickness (height) of the beam

HA=0.025 ! Thickness of the block
AB=0.06  !  Side length of the block square

T_DROP=SQRT(2*HB/9.8) ! Estimated time of the block dropping on the beam
TIME_0=0.0002  ! End of the first time interval
DTIME_0=0.0001 ! Time step for the first time interval
TIME_1=T_DROP! End of the second time interval
TIME_2=4*T_DROP! End of the third time interval

DTIME_1=TIME_1/10 ! Time step for the second time interval
DTIME_2=TIME_1/50! Time step for the third time interval

ET,1,BEAM3! 2D elastic beam element with degrees of freedom ux,uy,rotz 
ET,2,PLANE42,,,3 ! 2D quadrangular 4-node finite element with thickness for the block 
ET,3,CONTA175 ! 2-D/3-D Node-to-Surface Contact (for the block)
ET,4,TARGE169 ! 2-D target element (for the beam)

! Real constants sets
R,1,BL*HL,(BL*HL**3)/12,HL ! Cross-sectional area, moment of inertia and thickness (for the beam)
R,2,HA ! Thickness (for the block)
R,3, ! Default contact stiffness

! Material properties for material 1 - beam (copper)
MP,EX,1,1.2e11		! Young’s modulus
MP,DENS,1,8.9e3	! Density
MP,NUXY,1,0.33		! Poisson’s ratio

! Material properties for material 2 - block (steel)
MP,EX,2,2e11		! Young’s modulus
MP,DENS,2,7.88e3	! Density
MP,NUXY,2,0.29		! Poisson’s ratio

! Parameters of finite element mesh
NE_BEAM=30 !  Number of finite elements for the beam
NE_BLOCK=2 !  Number of finite elements for the block

! Solid and finite element model of the beam
K,1,0,0
K,2,LBEAM,0
L,1,2
! Associate with the beam: material type 1, FE type 1, real constant set 1
MAT,1 $ TYPE,1 $ REAL,1
ESIZE,,NE_BEAM ! Size of finite element for the beam
LMESH,ALL ! Mesh the beam

! Solid and finite element model of the block
RECTNG,L1,L1+AB,HB,HB+AB ! Rectangle by two keypoints RECTNG, X1, X2, Y1, Y2
! Associate with the block: material type 2, FE type 2, real constant set 2
MAT,2 $ TYPE,2 $ REAL,2
ESIZE,,NE_BLOCK ! Size of finite element for the block
AMESH,ALL ! Mesh the block area

! Generation of contact (CONTA171) and target (TARGE169) elements

! Creation of target elements on the beam
MAT,1 ! Select material 1 (beam)
TYPE,4 ! Set element type 4 (target)
REAL,3 ! Set real constant set 3
NSEL,S,LOC,Y,0 ! Select nodes with Y=0 (all nodes on the beam)
TSHAP,LINE ! Shape of target element - line
CM,BEAM,NODE ! Combine selected nodes into a group BEAM 
ESURF ! Generate target elements on the beam

ASEL,ALL ! Select all areas (block)
LSLA,S ! Select lines associated with selected area (boundary of the block)
nsll,s,1 ! Select nodes associated with selected areas
TYPE,3 ! Çàäàíèå òèïà ýëåìåíòà 3 (contact)
CM,PUNCH,NODE ! Combine selected nodes into a group PUNCH
ESURF ! Generate target elements on the block surface

ALLSEL,ALL ! Select everything


/SOLU
ANTYPE,TRANS     ! Transient problem
LUMPM,ON         ! Diagonal mass matrix (optional command)
NLGEOM,ON        ! Option of large displacements

! Boundary conditions for the beam
DK,1,ALL,0	
DK,2,UY,0

! Boundary conditions for the block
NSEL,S,LOC,Y,HB,HB+AB
D,ALL,ALL,0
NSEL,ALL

ACEL,,9.8   ! Take gravity acceleration into account

! First load step
! Calculation of preliminary stress-strain state
! Initial conditions for transient analysis
TIME,TIME_0 ! Time at the end of the first load step
DELTIM,DTIME_0 ! Time step
KBC,1 ! Loads are step changed (the same values for all substeps)
TIMINT,OFF ! No transient effects
outres,all,last ! Write results of the last substep into the database
SOLVE ! Solve the problem

! Select all nodes of the block
NSEL,S,LOC,Y,HB,HB+AB
DDELE,ALL,ALL ! Delete boundary conditions for the block
NSEL,ALL

OUTRES,ALL,ALL ! Write results of all substeps into the database
AUTOTS,ON ! Automatic time step
TIMINT,ON  ! Activate transient effects

! Second load step
TIME,TIME_1
DELTIM,DTIME_1,DTIME_1/5,DTIME_1*2 ! Time step, minimum and maximum time steps
SOLVE

! Third load step
TIME,TIME_2
DELTIM,DTIME_2,DTIME_2/10,DTIME_2 ! Time step, minimum and maximum time steps
SOLVE

FINISH