!*******************************************************************
!        Файл Buckl3.inp
! Определение критических сил и форм волнообразования
! при потере устойчивости пологой арки.
!   Eigenvalue Buckling Analysis
! (С учетом симметрии задачи рассматривается половина арки)
! Условия нагружения - распределенная нормальная нагрузка
!                  или сосредоточенная сила в верхней точке купола
!*******************************************************************
f_r='Buckl_p'        ! имя файлов для вывода результатов
nform=1           ! Количество первых значений критических сил
nldiv=40          ! Параметр для разбиения линий
! Все входные данные задаются в системе СГС
hl=0.3            ! Высота поперечного сечения арки
bl=1              ! Толщина поперечного сечения арки
hg=3.2            ! Высота купола арки
darc=20           ! Диаметр основания арки

rarc=hg/2+darc*darc/8/hg ! Радиус кривизны арки
pi=4*atan(1)  ! Число PI
alfar=acos((rarc-hg)/rarc) ! угол раствора половины арки в радианах
alfa=alfar*180/pi 	   ! угол раствора половины арки в градусах
larc=2*alfar*rarc          ! длина  арки
/output,f_r,res	! Сервисный вывод в файл <f_r>.res
*vwrite
(1X,'  Определение критических сил и форм волнообразования')
*vwrite
(1X,'  при потери устойчивости пологой арки.')
*vwrite
(1X,'  Eigenvalue Buckling Analysis ')
*vwrite
(1X)
*vwrite,darc,hg,hl,bl
(1X,'  DARC=', E12.5,'  HG=', E12.5,'  HL=', E12.5,' BL=', E12.5)
*vwrite,rarc
(1X,'  RARC=', E12.5)
*vwrite
(1X)
/output		! Окончание сервисного вывода

/prep7		
et,1,beam3			! КЭ BEAM3
mp,ex,1,2.02e6		! Модуль Юнга EX=2.02e6
mp,nuxy,1,0.3           ! Коэффициент Пуассона NUXY=0.3
r,1,bl*hl,(bl*hl**3)/12,hl	! R. const для поперечного сечения балки:
					! площадь, момент инерции, толщина
csys,1			! Переход в цилиндрическую систему координат
k,1,rarc,90			! Точка 1 - вершина купола
k,2,rarc,90-alfa		! Точка 2 - основание арки
n,1,rarc,90             ! Узел 1 будет далее узлом приложения силы,
n,2,rarc,90-alfa		! узел 2 - основанием арки

l,1,2,nldiv			! Генерация формы половины арки
! (В цилиндрической системе коорд. линии между точками
!  с одинаковыми радиусами есть дуги окружности)
lmesh,all		! Генерация сетки КЭ на линии
nummrg,node       ! Узлы 1,2 включаются в КЭ модель
finish		
! Этап определения геометрической матрицы жесткости S
/solu		
antype,static	! Статический тип анализа
pstres,on		! Включение расчета "предварительных напряжений" (S)
dk,1,ux,0,,,rotz   ! Условия симметрии в вершине купола арки
dk,2,ux,0,,,uy,rotz ! Жесткая заделка опорной точки 2 арки
! В случае действия сосредоточенной силы команду с sfbeam следует
!  закомментировать, а команду с f - раскомментировать.
!f,1,fy,-0.5	! Задание сжимающей силы в верхней точке (1) купола
! (Значение FY=-0.5, т.к. рассматривается половина модели)
sfbeam,all,,pres,0.5  ! Задание давления
! (pres=0.5, т.к. рассматривается половина модели)
outpr,,1  
solve
finish
! Этап определения точек бифуркации 
! линеаризированной задачи устойчивости
/solu
antype,buckle       ! Тип анализа - решение лин. задач устойчивости
bucopt,subsp,nform  ! Subspace-метод решения задачи 
!  на собственные значения с поиском nform собственных значений
outres,all,all		! Запись всех выходных данных
			! на всех шагах решения в базу данных
/pbc,all,1		! Показ всех граничных условий
/psf,pres,norm,1  ! Показ распределенных нагрузок
eplot			! Графический вывод конечно-элементной модели
solve		
finish		
/post1			! Постпроцессорная обработка результатов
! В цикле номерам по собственных значений считываются
! результаты для каждого собственного значения.
! Величины критических сил и/или нагрузок заносятся в файл вывода и
! рисуется форма потери устойчивости
*do,i,1,nform
  set,,i
  *get,fmode,mode,i,freq
! Для сосредоточенной силы следующие три команды
! следует раскомментрировать, а последующие четыре - закомментировать

!   /output,F_r,res,,append
!  *vwrite,i,fmode
!  (1X,F4.0,' Force=',E12.5)
  vforce=fmode*larc
  /output,F_r,res,,append
  *vwrite,i,fmode,vforce
  (1X,F4.0,' Pressure=',E12.5,' Total force=',E12.5)
  /output
  pldisp,1
*enddo